blob: 19a99ba91493bd2c695158576ea9edaef1ce9e05 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
@ECHO OFF
REM
REM Copyright (c) 2013 The ANGLE Project Authors. All rights reserved.
REM Use of this source code is governed by a BSD-style license that can be
REM found in the LICENSE file.
REM
PATH %PATH%;%ProgramFiles(x86)%\Windows Kits\8.1\bin\x86;%DXSDK_DIR%\Utilities\bin\x86
setlocal
set errorCount=0
set successCount=0
set debug=0
if "%1" == "debug" (
set debug=1
)
if "%1" == "release" (
set debug=0
)
:: | Input file | Entry point | Type | Output file | Debug |
call:BuildShader Blit.vs standardvs vs_2_0 compiled\standardvs.h %debug%
call:BuildShader Blit.vs flipyvs vs_2_0 compiled\flipyvs.h %debug%
call:BuildShader Blit.ps passthroughps ps_2_0 compiled\passthroughps.h %debug%
call:BuildShader Blit.ps luminanceps ps_2_0 compiled\luminanceps.h %debug%
call:BuildShader Blit.ps componentmaskps ps_2_0 compiled\componentmaskps.h %debug%
echo.
if %successCount% GTR 0 (
echo %successCount% shaders compiled successfully.
)
if %errorCount% GTR 0 (
echo There were %errorCount% shader compilation errors.
)
endlocal
exit /b
:BuildShader
set input=%~1
set entry=%~2
set type=%~3
set output=%~4
set debug=%~5
if %debug% == 0 (
set "buildCMD=fxc /nologo /E %entry% /T %type% /Fh %output% %input%"
) else (
set "buildCMD=fxc /nologo /Zi /Od /E %entry% /T %type% /Fh %output% %input%"
)
set error=0
%buildCMD% || set error=1
if %error% == 0 (
set /a successCount=%successCount%+1
) else (
set /a errorCount=%errorCount%+1
)
exit /b
|
