Remove Pale Moon from the Unified XUL Platform repository

Development will proceed at https://github.com/MoonchildProductions/Pale-Moon

8 files changed, 0 insertions, 3190 deletions

diff --git a/application/palemoon/installer/windows/Makefile.in b/application/palemoon/installer/windows/Makefile.in
deleted file mode 100644
index d2be8aec2..000000000
--- a/application/palemoon/installer/windows/Makefile.in
+++ /dev/null
@@ -1,69 +0,0 @@
-# This Source Code Form is subject to the terms of the Mozilla Public
-# License, v. 2.0. If a copy of the MPL was not distributed with this
-# file, You can obtain one at http://mozilla.org/MPL/2.0/.
-
-include $(topsrcdir)/toolkit/mozapps/installer/package-name.mk
-
-CONFIG_DIR = instgen
-SFX_MODULE = $(topsrcdir)/other-licenses/7zstub/palemoon/7zSD.sfx
-
-INSTALLER_FILES = \
-	app.tag \
-	nsis/installer.nsi \
-	nsis/uninstaller.nsi \
-	nsis/shared.nsh \
-	$(NULL)
-
-BRANDING_FILES = \
-	branding.nsi \
-	appname.bmp \
-	wizHeader.bmp \
-	wizHeaderRTL.bmp \
-	wizWatermark.bmp \
-	$(NULL)
-
-include $(topsrcdir)/config/config.mk
-
-ifdef LOCALE_MERGEDIR
-PPL_LOCALE_ARGS = \
-  --l10n-dir=$(LOCALE_MERGEDIR)/application/palemoon/installer \
-  --l10n-dir=$(call EXPAND_LOCALE_SRCDIR,application/palemoon/locales)/installer \
-  --l10n-dir=$(topsrcdir)/application/palemoon/locales/en-US/installer \
-  $(NULL)
-else
-PPL_LOCALE_ARGS=$(call EXPAND_LOCALE_SRCDIR,application/palemoon/locales)/installer
-endif
-
-OVERRIDE_DEFAULT_GOAL := installer
-installer::
-	$(MAKE) -C .. installer-stage
-	$(MAKE) $(CONFIG_DIR)/setup.exe
-
-# For building the uninstaller during the application build so it can be
-# included for mar file generation.
-uninstaller::
-	$(RM) -r $(CONFIG_DIR)
-	$(MKDIR) $(CONFIG_DIR)
-	$(INSTALL) $(addprefix $(srcdir)/,$(INSTALLER_FILES)) $(CONFIG_DIR)
-	$(INSTALL) $(addprefix $(DIST)/branding/,$(BRANDING_FILES)) $(CONFIG_DIR)
-	$(call py_action,preprocessor,-Fsubstitution $(DEFINES) $(ACDEFINES) \
-	  $(srcdir)/nsis/defines.nsi.in -o $(CONFIG_DIR)/defines.nsi)
-	$(PYTHON) $(topsrcdir)/toolkit/mozapps/installer/windows/nsis/preprocess-locale.py \
-	  --preprocess-locale $(topsrcdir) \
-	  $(PPL_LOCALE_ARGS) $(AB_CD) $(CONFIG_DIR)
-
-$(CONFIG_DIR)/setup.exe::
-	$(RM) -r $(CONFIG_DIR)
-	$(MKDIR) $(CONFIG_DIR)
-	$(INSTALL) $(addprefix $(srcdir)/,$(INSTALLER_FILES)) $(CONFIG_DIR)
-	$(INSTALL) $(addprefix $(DIST)/branding/,$(BRANDING_FILES)) $(CONFIG_DIR)
-	$(call py_action,preprocessor,-Fsubstitution $(DEFINES) $(ACDEFINES) \
-	  $(srcdir)/nsis/defines.nsi.in -o $(CONFIG_DIR)/defines.nsi)
-	$(PYTHON) $(topsrcdir)/toolkit/mozapps/installer/windows/nsis/preprocess-locale.py \
-	  --preprocess-locale $(topsrcdir) \
-	  $(PPL_LOCALE_ARGS) $(AB_CD) $(CONFIG_DIR)
-
-GARBARGE_DIRS += instgen
-
-include $(topsrcdir)/config/rules.mk
-include $(topsrcdir)/toolkit/mozapps/installer/windows/nsis/makensis.mk
diff --git a/application/palemoon/installer/windows/app.tag b/application/palemoon/installer/windows/app.tag
deleted file mode 100644
index 39235dbb0..000000000
--- a/application/palemoon/installer/windows/app.tag
+++ /dev/null
@@ -1,4 +0,0 @@
-;!@Install@!UTF-8!
-Title="Pale Moon"
-RunProgram="setup.exe"
-;!@InstallEnd@!
\ No newline at end of file
diff --git a/application/palemoon/installer/windows/moz.build b/application/palemoon/installer/windows/moz.build
deleted file mode 100644
index 394a85ccf..000000000
--- a/application/palemoon/installer/windows/moz.build
+++ /dev/null
@@ -1,15 +0,0 @@
-# -*- Mode: python; indent-tabs-mode: nil; tab-width: 40 -*-
-# vim: set filetype=python:
-# This Source Code Form is subject to the terms of the Mozilla Public
-# License, v. 2.0. If a copy of the MPL was not distributed with this
-# file, You can obtain one at http://mozilla.org/MPL/2.0/.
-
-DEFINES['MOZ_APP_NAME'] = CONFIG['MOZ_APP_NAME']
-DEFINES['APP_VERSION'] = CONFIG['MOZ_APP_VERSION']
-DEFINES['MOZILLA_VERSION'] = CONFIG['MOZILLA_VERSION']
-
-if CONFIG['MOZ_APP_DISPLAYNAME'] in ('PaleMoon', 'Palemoon'):
-  DEFINES['MOZ_APP_DISPLAYNAME'] = "Pale Moon"
-else:
-  DEFINES['MOZ_APP_DISPLAYNAME'] = CONFIG['MOZ_APP_DISPLAYNAME']
-
diff --git a/application/palemoon/installer/windows/nsis/defines.nsi.in b/application/palemoon/installer/windows/nsis/defines.nsi.in
deleted file mode 100644
index 1764b10c4..000000000
--- a/application/palemoon/installer/windows/nsis/defines.nsi.in
+++ /dev/null
@@ -1,65 +0,0 @@
-#filter substitution
-# This Source Code Form is subject to the terms of the Mozilla Public
-# License, v. 2.0. If a copy of the MPL was not distributed with this
-# file, You can obtain one at http://mozilla.org/MPL/2.0/.
-
-# These defines should match application.ini settings
-!define AppName               "Pale Moon"
-!define AppVersion            "@APP_VERSION@"
-!define GREVersion            @MOZILLA_VERSION@
-!define AB_CD                 "@AB_CD@"
-
-!define FileMainEXE           "@MOZ_APP_NAME@.exe"
-!define WindowClass           "Pale MoonMessageWindow"
-!define DDEApplication        "Pale Moon"
-!define AppRegName            "Pale Moon"
-
-!ifndef DEV_EDITION
-!define BrandShortName        "@MOZ_APP_DISPLAYNAME@"
-!endif
-!define BrandFullName         "${BrandFullNameInternal}"
-
-!define CERTIFICATE_NAME            "Mozilla Corporation"
-!define CERTIFICATE_ISSUER          "DigiCert SHA2 Assured ID Code Signing CA"
-; Changing the name or issuer requires us to have both the old and the new
-;  in the registry at the same time, temporarily.
-!define CERTIFICATE_NAME_PREVIOUS   "Mozilla Corporation"
-!define CERTIFICATE_ISSUER_PREVIOUS "DigiCert Assured ID Code Signing CA-1"
-
-# LSP_CATEGORIES is the permitted LSP categories for the application. Each LSP
-# category value is ANDed together to set multiple permitted categories.
-# See http://msdn.microsoft.com/en-us/library/ms742253%28VS.85%29.aspx
-# The value below removes all LSP categories previously set.
-!define LSP_CATEGORIES "0x00000000"
-
-!if "@MOZ_UPDATE_CHANNEL@" == ""
-!define UpdateChannel "Unknown"
-!else
-!define UpdateChannel "@MOZ_UPDATE_CHANNEL@"
-!endif
-
-# ARCH is used when it is necessary to differentiate the x64 registry keys from
-# the x86 registry keys (e.g. the uninstall registry key).
-#ifdef HAVE_64BIT_BUILD
-!define HAVE_64BIT_BUILD
-!define ARCH "x64"
-!define MinSupportedVer "Microsoft Windows 7 x64"
-#else
-!define ARCH "x86"
-!define MinSupportedVer "Microsoft Windows 7"
-#endif
-
-!define MinSupportedCPU "SSE2"
-
-# File details shared by both the installer and uninstaller
-VIProductVersion "1.0.0.0"
-VIAddVersionKey "ProductName"     "${BrandShortName}"
-VIAddVersionKey "CompanyName"     "${CompanyName}"
-#ifdef MOZ_OFFICIAL_BRANDING
-VIAddVersionKey "LegalTrademarks" "${BrandShortName} is a Trademark of Moonchild Productions."
-#endif
-VIAddVersionKey "LegalCopyright"  "${CompanyName}"
-VIAddVersionKey "FileVersion"     "${AppVersion}"
-VIAddVersionKey "ProductVersion"  "${AppVersion}"
-# Comments is not used but left below commented out for future reference
-# VIAddVersionKey "Comments"        "Comments"
diff --git a/application/palemoon/installer/windows/nsis/installer.nsi b/application/palemoon/installer/windows/nsis/installer.nsi
deleted file mode 100644
index 9f61c9cbb..000000000
--- a/application/palemoon/installer/windows/nsis/installer.nsi
+++ /dev/null
@@ -1,1162 +0,0 @@
-# This Source Code Form is subject to the terms of the Mozilla Public
-# License, v. 2.0. If a copy of the MPL was not distributed with this
-# file, You can obtain one at http://mozilla.org/MPL/2.0/.
-
-# Required Plugins:
-# AppAssocReg    http://nsis.sourceforge.net/Application_Association_Registration_plug-in
-# ApplicationID  http://nsis.sourceforge.net/ApplicationID_plug-in
-# CityHash       http://dxr.mozilla.org/mozilla-central/source/other-licenses/nsis/Contrib/CityHash
-# ShellLink      http://nsis.sourceforge.net/ShellLink_plug-in
-# UAC            http://nsis.sourceforge.net/UAC_plug-in
-# ServicesHelper Mozilla specific plugin that is located in /other-licenses/nsis
-
-; Set verbosity to 3 (e.g. no script) to lessen the noise in the build logs
-!verbose 3
-
-; 7-Zip provides better compression than the lzma from NSIS so we add the files
-; uncompressed and use 7-Zip to create a SFX archive of it
-SetDatablockOptimize on
-SetCompress off
-CRCCheck on
-
-RequestExecutionLevel user
-
-; The commands inside this ifdef require NSIS 3.0a2 or greater so the ifdef can
-; be removed after we require NSIS 3.0a2 or greater.
-!ifdef NSIS_PACKEDVERSION
-  Unicode true
-  ManifestSupportedOS all
-  ManifestDPIAware true
-!endif
-
-!addplugindir ./
-
-Var TmpVal
-Var InstallType
-Var AddStartMenuSC
-Var AddQuickLaunchSC
-Var AddDesktopSC
-Var InstallMaintenanceService
-Var PageName
-Var PreventRebootRequired
-
-; By defining NO_STARTMENU_DIR an installer that doesn't provide an option for
-; an application's Start Menu PROGRAMS directory and doesn't define the
-; StartMenuDir variable can use the common InstallOnInitCommon macro.
-!define NO_STARTMENU_DIR
-
-; On Vista and above attempt to elevate Standard Users in addition to users that
-; are a member of the Administrators group.
-!define NONADMIN_ELEVATE
-
-!define AbortSurveyURL "http://www.kampyle.com/feedback_form/ff-feedback-form.php?site_code=8166124&form_id=12116&url="
-
-; Other included files may depend upon these includes!
-; The following includes are provided by NSIS.
-!include FileFunc.nsh
-!include LogicLib.nsh
-!include MUI.nsh
-!include WinMessages.nsh
-!include WinVer.nsh
-!include WordFunc.nsh
-
-!insertmacro GetOptions
-!insertmacro GetParameters
-!insertmacro GetSize
-!insertmacro StrFilter
-!insertmacro WordFind
-!insertmacro WordReplace
-
-; The following includes are custom.
-!include branding.nsi
-!include defines.nsi
-!include common.nsh
-!include locales.nsi
-
-VIAddVersionKey "FileDescription" "${BrandShortName} Installer"
-VIAddVersionKey "OriginalFilename" "setup.exe"
-
-; Must be inserted before other macros that use logging
-!insertmacro _LoggingCommon
-
-!insertmacro AddDisabledDDEHandlerValues
-!insertmacro ChangeMUIHeaderImage
-!insertmacro CheckForFilesInUse
-!insertmacro CleanUpdateDirectories
-!insertmacro CopyFilesFromDir
-!insertmacro CreateRegKey
-!insertmacro GetLongPath
-!insertmacro GetPathFromString
-!insertmacro GetParent
-!insertmacro InitHashAppModelId
-!insertmacro IsHandlerForInstallDir
-!insertmacro IsPinnedToTaskBar
-!insertmacro LogDesktopShortcut
-!insertmacro LogQuickLaunchShortcut
-!insertmacro LogStartMenuShortcut
-!insertmacro ManualCloseAppPrompt
-!insertmacro PinnedToStartMenuLnkCount
-!insertmacro RegCleanAppHandler
-!insertmacro RegCleanMain
-!insertmacro RegCleanUninstall
-!insertmacro RemovePrecompleteEntries
-!insertmacro SetAppLSPCategories
-!insertmacro SetBrandNameVars
-!insertmacro UpdateShortcutAppModelIDs
-!insertmacro UnloadUAC
-!insertmacro WriteRegStr2
-!insertmacro WriteRegDWORD2
-
-!include shared.nsh
-
-; Helper macros for ui callbacks. Insert these after shared.nsh
-!insertmacro CheckCustomCommon
-!insertmacro InstallEndCleanupCommon
-!insertmacro InstallOnInitCommon
-!insertmacro InstallStartCleanupCommon
-!insertmacro LeaveDirectoryCommon
-!insertmacro LeaveOptionsCommon
-!insertmacro OnEndCommon
-!insertmacro PreDirectoryCommon
-
-Name "${BrandFullName}"
-OutFile "setup.exe"
-!ifdef HAVE_64BIT_BUILD
-  InstallDir "$PROGRAMFILES64\${BrandFullName}\"
-!else
-  InstallDir "$PROGRAMFILES32\${BrandFullName}\"
-!endif
-ShowInstDetails nevershow
-
-################################################################################
-# Modern User Interface - MUI
-
-!define MOZ_MUI_CUSTOM_ABORT
-!define MUI_CUSTOMFUNCTION_ABORT "CustomAbort"
-!define MUI_ICON setup.ico
-!define MUI_UNICON setup.ico
-!define MUI_WELCOMEPAGE_TITLE_3LINES
-!define MUI_HEADERIMAGE
-!define MUI_HEADERIMAGE_RIGHT
-!define MUI_WELCOMEFINISHPAGE_BITMAP wizWatermark.bmp
-
-; Use a right to left header image when the language is right to left
-!ifdef ${AB_CD}_rtl
-!define MUI_HEADERIMAGE_BITMAP_RTL wizHeaderRTL.bmp
-!else
-!define MUI_HEADERIMAGE_BITMAP wizHeader.bmp
-!endif
-
-/**
- * Installation Pages
- */
-; Welcome Page
-!define MUI_PAGE_CUSTOMFUNCTION_PRE preWelcome
-!insertmacro MUI_PAGE_WELCOME
-
-; Custom Options Page
-Page custom preOptions leaveOptions
-
-; Select Install Directory Page
-!define MUI_PAGE_CUSTOMFUNCTION_PRE preDirectory
-!define MUI_PAGE_CUSTOMFUNCTION_LEAVE leaveDirectory
-!define MUI_DIRECTORYPAGE_VERIFYONLEAVE
-!insertmacro MUI_PAGE_DIRECTORY
-
-; Custom Shortcuts Page
-Page custom preShortcuts leaveShortcuts
-
-; Custom Summary Page
-Page custom preSummary leaveSummary
-
-; Install Files Page
-!insertmacro MUI_PAGE_INSTFILES
-
-; Finish Page
-!define MUI_FINISHPAGE_TITLE_3LINES
-!define MUI_FINISHPAGE_RUN
-!define MUI_FINISHPAGE_RUN_FUNCTION LaunchApp
-!define MUI_FINISHPAGE_RUN_TEXT $(LAUNCH_TEXT)
-!define MUI_PAGE_CUSTOMFUNCTION_PRE preFinish
-!insertmacro MUI_PAGE_FINISH
-
-; Use the default dialog for IDD_VERIFY for a simple Banner
-ChangeUI IDD_VERIFY "${NSISDIR}\Contrib\UIs\default.exe"
-
-################################################################################
-# Install Sections
-
-; Cleanup operations to perform at the start of the installation.
-Section "-InstallStartCleanup"
-  SetDetailsPrint both
-  DetailPrint $(STATUS_CLEANUP)
-  SetDetailsPrint none
-
-  SetOutPath "$INSTDIR"
-  ${StartInstallLog} "${BrandFullName}" "${AB_CD}" "${AppVersion}" "${GREVersion}"
-
-  StrCpy $R9 "true"
-  StrCpy $PreventRebootRequired "false"
-  ${GetParameters} $R8
-  ${GetOptions} "$R8" "/INI=" $R7
-  ${Unless} ${Errors}
-    ; The configuration file must also exist
-    ${If} ${FileExists} "$R7"
-      ReadINIStr $R9 $R7 "Install" "RemoveDistributionDir"
-      ReadINIStr $R8 $R7 "Install" "PreventRebootRequired"
-      ${If} $R8 == "true"
-        StrCpy $PreventRebootRequired "true"
-      ${EndIf}
-    ${EndIf}
-  ${EndUnless}
-
-  ; Remove directories and files we always control before parsing the uninstall
-  ; log so empty directories can be removed.
-  ${If} ${FileExists} "$INSTDIR\updates"
-    RmDir /r "$INSTDIR\updates"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\updated"
-    RmDir /r "$INSTDIR\updated"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\defaults\shortcuts"
-    RmDir /r "$INSTDIR\defaults\shortcuts"
-  ${EndIf}
-  ; Only remove the distribution directory if it exists and if the installer
-  ; isn't launched with an ini file that has RemoveDistributionDir=false in the
-  ; install section.
-  ${If} ${FileExists} "$INSTDIR\distribution"
-  ${AndIf} $R9 != "false"
-    RmDir /r "$INSTDIR\distribution"
-  ${EndIf}
-
-  ; Delete the app exe if present to prevent launching the app while we are
-  ; installing.
-  ClearErrors
-  ${DeleteFile} "$INSTDIR\${FileMainEXE}"
-  ${If} ${Errors}
-    ; If the user closed the application it can take several seconds for it to
-    ; shut down completely. If the application is being used by another user we
-    ; can rename the file and then delete is when the system is restarted.
-    Sleep 5000
-    ${DeleteFile} "$INSTDIR\${FileMainEXE}"
-    ClearErrors
-  ${EndIf}
-
-  ; setup the application model id registration value
-  ${InitHashAppModelId} "$INSTDIR" "Software\Mozilla\${AppName}\TaskBarIDs"
-
-  ; Remove the updates directory for Vista and above
-  ${CleanUpdateDirectories} "Mozilla\Pale Moon" "Mozilla\updates"
-
-  ${RemoveDeprecatedFiles}
-  ${RemovePrecompleteEntries} "false"
-
-  ${If} ${FileExists} "$INSTDIR\defaults\pref\channel-prefs.js"
-    Delete "$INSTDIR\defaults\pref\channel-prefs.js"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\defaults\pref"
-    RmDir "$INSTDIR\defaults\pref"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\defaults"
-    RmDir "$INSTDIR\defaults"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\uninstall"
-    ; Remove the uninstall directory that we control
-    RmDir /r "$INSTDIR\uninstall"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\update-settings.ini"
-    Delete "$INSTDIR\update-settings.ini"
-  ${EndIf}
-
-  ; Explictly remove empty webapprt dir in case it exists (bug 757978).
-  RmDir "$INSTDIR\webapprt\components"
-  RmDir "$INSTDIR\webapprt"
-
-  ${InstallStartCleanupCommon}
-SectionEnd
-
-Section "-Application" APP_IDX
-  ${StartUninstallLog}
-
-  SetDetailsPrint both
-  DetailPrint $(STATUS_INSTALL_APP)
-  SetDetailsPrint none
-
-  ${LogHeader} "Installing Main Files"
-  ${CopyFilesFromDir} "$EXEDIR\core" "$INSTDIR" \
-                      "$(ERROR_CREATE_DIRECTORY_PREFIX)" \
-                      "$(ERROR_CREATE_DIRECTORY_SUFFIX)"
-
-  ; Register DLLs
-  ; XXXrstrong - AccessibleMarshal.dll can be used by multiple applications but
-  ; is only registered for the last application installed. When the last
-  ; application installed is uninstalled AccessibleMarshal.dll will no longer be
-  ; registered. bug 338878
-  ${LogHeader} "DLL Registration"
-  ClearErrors
-  ${RegisterDLL} "$INSTDIR\AccessibleMarshal.dll"
-  ${If} ${Errors}
-    ${LogMsg} "** ERROR Registering: $INSTDIR\AccessibleMarshal.dll **"
-  ${Else}
-    ${LogUninstall} "DLLReg: \AccessibleMarshal.dll"
-    ${LogMsg} "Registered: $INSTDIR\AccessibleMarshal.dll"
-  ${EndIf}
-
-  ClearErrors
-
-  ; Default for creating Start Menu shortcut
-  ; (1 = create, 0 = don't create)
-  ${If} $AddStartMenuSC == ""
-    StrCpy $AddStartMenuSC "1"
-  ${EndIf}
-
-  ; Default for creating Quick Launch shortcut (1 = create, 0 = don't create)
-  ${If} $AddQuickLaunchSC == ""
-    ; Don't install the quick launch shortcut on Windows 7
-    ${If} ${AtLeastWin7}
-      StrCpy $AddQuickLaunchSC "0"
-    ${Else}
-      StrCpy $AddQuickLaunchSC "1"
-    ${EndIf}
-  ${EndIf}
-
-  ; Default for creating Desktop shortcut (1 = create, 0 = don't create)
-  ${If} $AddDesktopSC == ""
-    StrCpy $AddDesktopSC "1"
-  ${EndIf}
-
-  ${LogHeader} "Adding Registry Entries"
-  SetShellVarContext current  ; Set SHCTX to HKCU
-  ${RegCleanMain} "Software\Mozilla"
-  ${RegCleanUninstall}
-  ${UpdateProtocolHandlers}
-
-  ClearErrors
-  WriteRegStr HKLM "Software\Mozilla" "${BrandShortName}InstallerTest" "Write Test"
-  ${If} ${Errors}
-    StrCpy $TmpVal "HKCU" ; used primarily for logging
-  ${Else}
-    SetShellVarContext all  ; Set SHCTX to HKLM
-    DeleteRegValue HKLM "Software\Mozilla" "${BrandShortName}InstallerTest"
-    StrCpy $TmpVal "HKLM" ; used primarily for logging
-    ${RegCleanMain} "Software\Mozilla"
-    ${RegCleanUninstall}
-    ${UpdateProtocolHandlers}
-
-    ReadRegStr $0 HKLM "Software\mozilla.org\Mozilla" "CurrentVersion"
-    ${If} "$0" != "${GREVersion}"
-      WriteRegStr HKLM "Software\mozilla.org\Mozilla" "CurrentVersion" "${GREVersion}"
-    ${EndIf}
-  ${EndIf}
-
-  ${RemoveDeprecatedKeys}
-
-  ; The previous installer adds several regsitry values to both HKLM and HKCU.
-  ; We now try to add to HKLM and if that fails to HKCU
-
-  ; The order that reg keys and values are added is important if you use the
-  ; uninstall log to remove them on uninstall. When using the uninstall log you
-  ; MUST add children first so they will be removed first on uninstall so they
-  ; will be empty when the key is deleted. This allows the uninstaller to
-  ; specify that only empty keys will be deleted.
-  ${SetAppKeys}
-
-  ${FixClassKeys}
-
-  ; Uninstall keys can only exist under HKLM on some versions of windows. Since
-  ; it doesn't cause problems always add them.
-  ${SetUninstallKeys}
-
-  ; On install always add the PaleMoonHTML and PaleMoonURL keys.
-  ; An empty string is used for the 5th param because PaleMoonHTML is not a
-  ; protocol handler.
-  ${GetLongPath} "$INSTDIR\${FileMainEXE}" $8
-  StrCpy $2 "$\"$8$\" -osint -url $\"%1$\""
-
-  ; In Win8, the delegate execute handler picks up the value in PaleMoonURL and
-  ; PaleMoonHTML to launch the desktop browser when it needs to.
-  ${AddDisabledDDEHandlerValues} "PaleMoonHTML" "$2" "$8,1" \
-                                 "${AppRegName} Document" ""
-  ${AddDisabledDDEHandlerValues} "PaleMoonURL" "$2" "$8,1" "${AppRegName} URL" \
-                                 "true"
-
-  ; For pre win8, the following keys should only be set if we can write to HKLM.
-  ; For post win8, the keys below get set in both HKLM and HKCU.
-  ${If} $TmpVal == "HKLM"
-    ; Set the Start Menu Internet and Vista Registered App HKLM registry keys.
-    ${SetStartMenuInternet} "HKLM"
-    ${FixShellIconHandler} "HKLM"
-
-    ; If we are writing to HKLM and create either the desktop or start menu
-    ; shortcuts set IconsVisible to 1 otherwise to 0.
-    ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-    StrCpy $0 "Software\Clients\StartMenuInternet\$R9\InstallInfo"
-    ${If} $AddDesktopSC == 1
-    ${OrIf} $AddStartMenuSC == 1
-      WriteRegDWORD HKLM "$0" "IconsVisible" 1
-    ${Else}
-      WriteRegDWORD HKLM "$0" "IconsVisible" 0
-    ${EndIf}
-  ${EndIf}
-
-  ${If} ${AtLeastWin8}
-    ; Set the Start Menu Internet and Vista Registered App HKCU registry keys.
-    ${SetStartMenuInternet} "HKCU"
-    ${FixShellIconHandler} "HKCU"
-
-    ; If we create either the desktop or start menu shortcuts, then
-    ; set IconsVisible to 1 otherwise to 0.
-    ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-    StrCpy $0 "Software\Clients\StartMenuInternet\$R9\InstallInfo"
-    ${If} $AddDesktopSC == 1
-    ${OrIf} $AddStartMenuSC == 1
-      WriteRegDWORD HKCU "$0" "IconsVisible" 1
-    ${Else}
-      WriteRegDWORD HKCU "$0" "IconsVisible" 0
-    ${EndIf}
-  ${EndIf}
-
-  ; These need special handling on uninstall since they may be overwritten by
-  ; an install into a different location.
-  StrCpy $0 "Software\Microsoft\Windows\CurrentVersion\App Paths\${FileMainEXE}"
-  ${WriteRegStr2} $TmpVal "$0" "" "$INSTDIR\${FileMainEXE}" 0
-  ${WriteRegStr2} $TmpVal "$0" "Path" "$INSTDIR" 0
-
-  StrCpy $0 "Software\Microsoft\MediaPlayer\ShimInclusionList\$R9"
-  ${CreateRegKey} "$TmpVal" "$0" 0
-  StrCpy $0 "Software\Microsoft\MediaPlayer\ShimInclusionList\plugin-container.exe"
-  ${CreateRegKey} "$TmpVal" "$0" 0
-
-  ${If} $TmpVal == "HKLM"
-    ; Set the permitted LSP Categories for WinVista and above
-    ${SetAppLSPCategories} ${LSP_CATEGORIES}
-  ${EndIf}
-
-  ; Create shortcuts
-  ${LogHeader} "Adding Shortcuts"
-
-  ; Remove the start menu shortcuts and directory if the SMPROGRAMS section
-  ; exists in the shortcuts_log.ini and the SMPROGRAMS. The installer's shortcut
-  ; creation code will create the shortcut in the root of the Start Menu
-  ; Programs directory.
-  ${RemoveStartMenuDir}
-
-  ; Always add the application's shortcuts to the shortcuts log ini file. The
-  ; DeleteShortcuts macro will do the right thing on uninstall if the
-  ; shortcuts don't exist.
-  ${LogStartMenuShortcut} "${BrandFullName}.lnk"
-  ${LogQuickLaunchShortcut} "${BrandFullName}.lnk"
-  ${LogDesktopShortcut} "${BrandFullName}.lnk"
-
-  ; Best effort to update the Win7 taskbar and start menu shortcut app model
-  ; id's. The possible contexts are current user / system and the user that
-  ; elevated the installer.
-  Call FixShortcutAppModelIDs
-  ; If the current context is all also perform Win7 taskbar and start menu link
-  ; maintenance for the current user context.
-  ${If} $TmpVal == "HKLM"
-    SetShellVarContext current  ; Set SHCTX to HKCU
-    Call FixShortcutAppModelIDs
-    SetShellVarContext all  ; Set SHCTX to HKLM
-  ${EndIf}
-
-  ; If running elevated also perform Win7 taskbar and start menu link
-  ; maintenance for the unelevated user context in case that is different than
-  ; the current user.
-  ClearErrors
-  ${GetParameters} $0
-  ${GetOptions} "$0" "/UAC:" $0
-  ${Unless} ${Errors}
-    GetFunctionAddress $0 FixShortcutAppModelIDs
-    UAC::ExecCodeSegment $0
-  ${EndUnless}
-
-  ; UAC only allows elevating to an Admin account so there is no need to add
-  ; the Start Menu or Desktop shortcuts from the original unelevated process
-  ; since this will either add it for the user if unelevated or All Users if
-  ; elevated.
-  ${If} $AddStartMenuSC == 1
-    CreateShortCut "$SMPROGRAMS\${BrandFullName}.lnk" "$INSTDIR\${FileMainEXE}"
-    ${If} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-      ShellLink::SetShortCutWorkingDirectory "$SMPROGRAMS\${BrandFullName}.lnk" \
-                                           "$INSTDIR"
-      ${If} ${AtLeastWin7}
-      ${AndIf} "$AppUserModelID" != ""
-        ApplicationID::Set "$SMPROGRAMS\${BrandFullName}.lnk" "$AppUserModelID" "true"
-      ${EndIf}
-      ${LogMsg} "Added Shortcut: $SMPROGRAMS\${BrandFullName}.lnk"
-    ${Else}
-      ${LogMsg} "** ERROR Adding Shortcut: $SMPROGRAMS\${BrandFullName}.lnk"
-    ${EndIf}
-  ${EndIf}
-
-  ; Update lastwritetime of the Start Menu shortcut to clear the tile cache.
-  ${If} ${AtLeastWin8}
-  ${AndIf} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-    FileOpen $0 "$SMPROGRAMS\${BrandFullName}.lnk" a
-    FileClose $0
-  ${EndIf}
-
-  ${If} $AddDesktopSC == 1
-    CreateShortCut "$DESKTOP\${BrandFullName}.lnk" "$INSTDIR\${FileMainEXE}"
-    ${If} ${FileExists} "$DESKTOP\${BrandFullName}.lnk"
-      ShellLink::SetShortCutWorkingDirectory "$DESKTOP\${BrandFullName}.lnk" \
-                                             "$INSTDIR"
-      ${If} ${AtLeastWin7}
-      ${AndIf} "$AppUserModelID" != ""
-        ApplicationID::Set "$DESKTOP\${BrandFullName}.lnk" "$AppUserModelID"  "true"
-      ${EndIf}
-      ${LogMsg} "Added Shortcut: $DESKTOP\${BrandFullName}.lnk"
-    ${Else}
-      ${LogMsg} "** ERROR Adding Shortcut: $DESKTOP\${BrandFullName}.lnk"
-    ${EndIf}
-  ${EndIf}
-
-  ; If elevated the Quick Launch shortcut must be added from the unelevated
-  ; original process.
-  ${If} $AddQuickLaunchSC == 1
-    ${Unless} ${AtLeastWin7}
-      ClearErrors
-      ${GetParameters} $0
-      ${GetOptions} "$0" "/UAC:" $0
-      ${If} ${Errors}
-        Call AddQuickLaunchShortcut
-        ${LogMsg} "Added Shortcut: $QUICKLAUNCH\${BrandFullName}.lnk"
-      ${Else}
-        ; It is not possible to add a log entry from the unelevated process so
-        ; add the log entry without the path since there is no simple way to
-        ; know the correct full path.
-        ${LogMsg} "Added Quick Launch Shortcut: ${BrandFullName}.lnk"
-        GetFunctionAddress $0 AddQuickLaunchShortcut
-        UAC::ExecCodeSegment $0
-      ${EndIf}
-    ${EndUnless}
-  ${EndIf}
-SectionEnd
-
-; Cleanup operations to perform at the end of the installation.
-Section "-InstallEndCleanup"
-  SetDetailsPrint both
-  DetailPrint "$(STATUS_CLEANUP)"
-  SetDetailsPrint none
-
-  ${Unless} ${Silent}
-    ClearErrors
-    ${MUI_INSTALLOPTIONS_READ} $0 "summary.ini" "Field 4" "State"
-    ${If} "$0" == "1"
-      ; NB: this code is duplicated in stub.nsi. Please keep in sync.
-      ; For data migration in the app, we want to know what the default browser
-      ; value was before we changed it. To do so, we read it here and store it
-      ; in our own registry key.
-      StrCpy $0 ""
-      ${If} ${AtLeastWinVista}
-        AppAssocReg::QueryCurrentDefault "http" "protocol" "effective"
-        Pop $1
-        ; If the method hasn't failed, $1 will contain the progid. Check:
-        ${If} "$1" != "method failed"
-        ${AndIf} "$1" != "method not available"
-          ; Read the actual command from the progid
-          ReadRegStr $0 HKCR "$1\shell\open\command" ""
-        ${EndIf}
-      ${EndIf}
-      ; If using the App Association Registry didn't happen or failed, fall back
-      ; to the effective http default:
-      ${If} "$0" == ""
-        ReadRegStr $0 HKCR "http\shell\open\command" ""
-      ${EndIf}
-      ; If we have something other than empty string now, write the value.
-      ${If} "$0" != ""
-        ClearErrors
-        WriteRegStr HKCU "Software\Mozilla\Pale Moon" "OldDefaultBrowserCommand" "$0"
-      ${EndIf}
-
-      ${LogHeader} "Setting as the default browser"
-      ClearErrors
-      ${GetParameters} $0
-      ${GetOptions} "$0" "/UAC:" $0
-      ${If} ${Errors}
-        Call SetAsDefaultAppUserHKCU
-      ${Else}
-        GetFunctionAddress $0 SetAsDefaultAppUserHKCU
-        UAC::ExecCodeSegment $0
-      ${EndIf}
-    ${ElseIfNot} ${Errors}
-      ${LogHeader} "Writing default-browser opt-out"
-      ClearErrors
-      WriteRegStr HKCU "Software\Mozilla\Pale Moon" "DefaultBrowserOptOut" "True"
-      ${If} ${Errors}
-        ${LogMsg} "Error writing default-browser opt-out"
-      ${EndIf}
-    ${EndIf}
-  ${EndUnless}
-
-  ; Adds a pinned Task Bar shortcut (see MigrateTaskBarShortcut for details).
-  ${MigrateTaskBarShortcut}
-
-  ; Add the Firewall entries during install
-  Call AddFirewallEntries
-
-  ; Refresh desktop icons
-  System::Call "shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_DWORDFLUSH}, i 0, i 0)"
-
-  ${InstallEndCleanupCommon}
-
-  ${If} $PreventRebootRequired == "true"
-    SetRebootFlag false
-  ${EndIf}
-
-  ${If} ${RebootFlag}
-    ; Admin is required to delete files on reboot so only add the moz-delete if
-    ; the user is an admin. After calling UAC::IsAdmin $0 will equal 1 if the
-    ; user is an admin.
-    UAC::IsAdmin
-    ${If} "$0" == "1"
-      ; When a reboot is required give SHChangeNotify time to finish the
-      ; refreshing the icons so the OS doesn't display the icons from helper.exe
-      Sleep 10000
-      ${LogHeader} "Reboot Required To Finish Installation"
-      ; ${FileMainEXE}.moz-upgrade should never exist but just in case...
-      ${Unless} ${FileExists} "$INSTDIR\${FileMainEXE}.moz-upgrade"
-        Rename "$INSTDIR\${FileMainEXE}" "$INSTDIR\${FileMainEXE}.moz-upgrade"
-      ${EndUnless}
-
-      ${If} ${FileExists} "$INSTDIR\${FileMainEXE}"
-        ClearErrors
-        Rename "$INSTDIR\${FileMainEXE}" "$INSTDIR\${FileMainEXE}.moz-delete"
-        ${Unless} ${Errors}
-          Delete /REBOOTOK "$INSTDIR\${FileMainEXE}.moz-delete"
-        ${EndUnless}
-      ${EndIf}
-
-      ${Unless} ${FileExists} "$INSTDIR\${FileMainEXE}"
-        CopyFiles /SILENT "$INSTDIR\uninstall\helper.exe" "$INSTDIR"
-        FileOpen $0 "$INSTDIR\${FileMainEXE}" w
-        FileWrite $0 "Will be deleted on restart"
-        Rename /REBOOTOK "$INSTDIR\${FileMainEXE}.moz-upgrade" "$INSTDIR\${FileMainEXE}"
-        FileClose $0
-        Delete "$INSTDIR\${FileMainEXE}"
-        Rename "$INSTDIR\helper.exe" "$INSTDIR\${FileMainEXE}"
-      ${EndUnless}
-    ${EndIf}
-  ${EndIf}
-SectionEnd
-
-################################################################################
-# Install Abort Survey Functions
-
-Function CustomAbort
-  ${If} "${AB_CD}" == "en-US"
-  ${AndIf} "$PageName" != ""
-  ${AndIf} ${FileExists} "$EXEDIR\core\distribution\distribution.ini"
-    ReadINIStr $0 "$EXEDIR\core\distribution\distribution.ini" "Global" "about"
-    ClearErrors
-    ${WordFind} "$0" "Funnelcake" "E#" $1
-    ${Unless} ${Errors}
-      ; Yes = fill out the survey and exit, No = don't fill out survey and exit,
-      ; Cancel = don't exit.
-      MessageBox MB_YESNO|MB_ICONEXCLAMATION \
-                 "Would you like to tell us why you are canceling this installation?" \
-                 IDYes +1 IDNO CustomAbort_finish
-      ${If} "$PageName" == "Welcome"
-          GetFunctionAddress $0 AbortSurveyWelcome
-      ${ElseIf} "$PageName" == "Options"
-          GetFunctionAddress $0 AbortSurveyOptions
-      ${ElseIf} "$PageName" == "Directory"
-          GetFunctionAddress $0 AbortSurveyDirectory
-      ${ElseIf} "$PageName" == "Shortcuts"
-          GetFunctionAddress $0 AbortSurveyShortcuts
-      ${ElseIf} "$PageName" == "Summary"
-          GetFunctionAddress $0 AbortSurveySummary
-      ${EndIf}
-      ClearErrors
-      ${GetParameters} $1
-      ${GetOptions} "$1" "/UAC:" $2
-      ${If} ${Errors}
-        Call $0
-      ${Else}
-        UAC::ExecCodeSegment $0
-      ${EndIf}
-
-      CustomAbort_finish:
-      Return
-    ${EndUnless}
-  ${EndIf}
-
-  MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(MOZ_MUI_TEXT_ABORTWARNING)" \
-             IDYES +1 IDNO +2
-  Return
-  Abort
-FunctionEnd
-
-Function AbortSurveyWelcome
-  ExecShell "open" "${AbortSurveyURL}step1"
-FunctionEnd
-
-Function AbortSurveyOptions
-  ExecShell "open" "${AbortSurveyURL}step2"
-FunctionEnd
-
-Function AbortSurveyDirectory
-  ExecShell "open" "${AbortSurveyURL}step3"
-FunctionEnd
-
-Function AbortSurveyShortcuts
-  ExecShell "open" "${AbortSurveyURL}step4"
-FunctionEnd
-
-Function AbortSurveySummary
-  ExecShell "open" "${AbortSurveyURL}step5"
-FunctionEnd
-
-################################################################################
-# Helper Functions
-
-Function AddQuickLaunchShortcut
-  CreateShortCut "$QUICKLAUNCH\${BrandFullName}.lnk" "$INSTDIR\${FileMainEXE}"
-  ${If} ${FileExists} "$QUICKLAUNCH\${BrandFullName}.lnk"
-    ShellLink::SetShortCutWorkingDirectory "$QUICKLAUNCH\${BrandFullName}.lnk" \
-                                           "$INSTDIR"
-  ${EndIf}
-FunctionEnd
-
-Function CheckExistingInstall
-  ; If there is a pending file copy from a previous upgrade don't allow
-  ; installing until after the system has rebooted.
-  IfFileExists "$INSTDIR\${FileMainEXE}.moz-upgrade" +1 +4
-  MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(WARN_RESTART_REQUIRED_UPGRADE)" IDNO +2
-  Reboot
-  Quit
-
-  ; If there is a pending file deletion from a previous uninstall don't allow
-  ; installing until after the system has rebooted.
-  IfFileExists "$INSTDIR\${FileMainEXE}.moz-delete" +1 +4
-  MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(WARN_RESTART_REQUIRED_UNINSTALL)" IDNO +2
-  Reboot
-  Quit
-
-  ${If} ${FileExists} "$INSTDIR\${FileMainEXE}"
-    ; Disable the next, cancel, and back buttons
-    GetDlgItem $0 $HWNDPARENT 1 ; Next button
-    EnableWindow $0 0
-    GetDlgItem $0 $HWNDPARENT 2 ; Cancel button
-    EnableWindow $0 0
-    GetDlgItem $0 $HWNDPARENT 3 ; Back button
-    EnableWindow $0 0
-
-    Banner::show /NOUNLOAD "$(BANNER_CHECK_EXISTING)"
-
-    ${If} "$TmpVal" == "FoundMessageWindow"
-      Sleep 5000
-    ${EndIf}
-
-    ${PushFilesToCheck}
-
-    ; Store the return value in $TmpVal so it is less likely to be accidentally
-    ; overwritten elsewhere.
-    ${CheckForFilesInUse} $TmpVal
-
-    Banner::destroy
-
-    ; Enable the next, cancel, and back buttons
-    GetDlgItem $0 $HWNDPARENT 1 ; Next button
-    EnableWindow $0 1
-    GetDlgItem $0 $HWNDPARENT 2 ; Cancel button
-    EnableWindow $0 1
-    GetDlgItem $0 $HWNDPARENT 3 ; Back button
-    EnableWindow $0 1
-
-    ${If} "$TmpVal" == "true"
-      StrCpy $TmpVal "FoundMessageWindow"
-      ${ManualCloseAppPrompt} "${WindowClass}" "$(WARN_MANUALLY_CLOSE_APP_INSTALL)"
-      StrCpy $TmpVal "true"
-    ${EndIf}
-  ${EndIf}
-FunctionEnd
-
-Function LaunchApp
-!ifndef DEV_EDITION
-  ${ManualCloseAppPrompt} "${WindowClass}" "$(WARN_MANUALLY_CLOSE_APP_LAUNCH)"
-!endif
-
-  ClearErrors
-  ${GetParameters} $0
-  ${GetOptions} "$0" "/UAC:" $1
-  ${If} ${Errors}
-    Exec "$\"$INSTDIR\${FileMainEXE}$\""
-  ${Else}
-    GetFunctionAddress $0 LaunchAppFromElevatedProcess
-    UAC::ExecCodeSegment $0
-  ${EndIf}
-FunctionEnd
-
-Function LaunchAppFromElevatedProcess
-  ; Find the installation directory when launching using GetFunctionAddress
-  ; from an elevated installer since $INSTDIR will not be set in this installer
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-  ReadRegStr $0 HKLM "Software\Clients\StartMenuInternet\$R9\DefaultIcon" ""
-  ${GetPathFromString} "$0" $0
-  ${GetParent} "$0" $1
-  ; Set our current working directory to the application's install directory
-  ; otherwise the 7-Zip temp directory will be in use and won't be deleted.
-  SetOutPath "$1"
-  Exec "$\"$0$\""
-FunctionEnd
-
-################################################################################
-# Language
-
-!insertmacro MOZ_MUI_LANGUAGE 'baseLocale'
-!verbose push
-!verbose 3
-!include "overrideLocale.nsh"
-!include "customLocale.nsh"
-!verbose pop
-
-; Set this after the locale files to override it if it is in the locale
-; using " " for BrandingText will hide the "Nullsoft Install System..." branding
-BrandingText " "
-
-################################################################################
-# Page pre, show, and leave functions
-
-Function preWelcome
-  StrCpy $PageName "Welcome"
-  ${If} ${FileExists} "$EXEDIR\core\distribution\modern-wizard.bmp"
-    Delete "$PLUGINSDIR\modern-wizard.bmp"
-    CopyFiles /SILENT "$EXEDIR\core\distribution\modern-wizard.bmp" "$PLUGINSDIR\modern-wizard.bmp"
-  ${EndIf}
-FunctionEnd
-
-Function preOptions
-  StrCpy $PageName "Options"
-  ${If} ${FileExists} "$EXEDIR\core\distribution\modern-header.bmp"
-  ${AndIf} $hHeaderBitmap == ""
-    Delete "$PLUGINSDIR\modern-header.bmp"
-    CopyFiles /SILENT "$EXEDIR\core\distribution\modern-header.bmp" "$PLUGINSDIR\modern-header.bmp"
-    ${ChangeMUIHeaderImage} "$PLUGINSDIR\modern-header.bmp"
-  ${EndIf}
-  !insertmacro MUI_HEADER_TEXT "$(OPTIONS_PAGE_TITLE)" "$(OPTIONS_PAGE_SUBTITLE)"
-  !insertmacro MUI_INSTALLOPTIONS_DISPLAY "options.ini"
-FunctionEnd
-
-Function leaveOptions
-  ${MUI_INSTALLOPTIONS_READ} $0 "options.ini" "Settings" "State"
-  ${If} $0 != 0
-    Abort
-  ${EndIf}
-  ${MUI_INSTALLOPTIONS_READ} $R0 "options.ini" "Field 2" "State"
-  StrCmp $R0 "1" +1 +2
-  StrCpy $InstallType ${INSTALLTYPE_BASIC}
-  ${MUI_INSTALLOPTIONS_READ} $R0 "options.ini" "Field 3" "State"
-  StrCmp $R0 "1" +1 +2
-  StrCpy $InstallType ${INSTALLTYPE_CUSTOM}
-
-  ${LeaveOptionsCommon}
-
-  ${If} $InstallType == ${INSTALLTYPE_BASIC}
-    Call CheckExistingInstall
-  ${EndIf}
-FunctionEnd
-
-Function preDirectory
-  StrCpy $PageName "Directory"
-  ${PreDirectoryCommon}
-FunctionEnd
-
-Function leaveDirectory
-  ${If} $InstallType == ${INSTALLTYPE_BASIC}
-    Call CheckExistingInstall
-  ${EndIf}
-  ${LeaveDirectoryCommon} "$(WARN_DISK_SPACE)" "$(WARN_WRITE_ACCESS)"
-FunctionEnd
-
-Function preShortcuts
-  StrCpy $PageName "Shortcuts"
-  ${CheckCustomCommon}
-  !insertmacro MUI_HEADER_TEXT "$(SHORTCUTS_PAGE_TITLE)" "$(SHORTCUTS_PAGE_SUBTITLE)"
-  !insertmacro MUI_INSTALLOPTIONS_DISPLAY "shortcuts.ini"
-FunctionEnd
-
-Function leaveShortcuts
-  ${MUI_INSTALLOPTIONS_READ} $0 "shortcuts.ini" "Settings" "State"
-  ${If} $0 != 0
-    Abort
-  ${EndIf}
-  ${MUI_INSTALLOPTIONS_READ} $AddDesktopSC "shortcuts.ini" "Field 2" "State"
-  ${MUI_INSTALLOPTIONS_READ} $AddStartMenuSC "shortcuts.ini" "Field 3" "State"
-
-  ; Don't install the quick launch shortcut on Windows 7
-  ${Unless} ${AtLeastWin7}
-    ${MUI_INSTALLOPTIONS_READ} $AddQuickLaunchSC "shortcuts.ini" "Field 4" "State"
-  ${EndUnless}
-
-  ${If} $InstallType == ${INSTALLTYPE_CUSTOM}
-    Call CheckExistingInstall
-  ${EndIf}
-FunctionEnd
-
-Function preSummary
-  StrCpy $PageName "Summary"
-  ; Setup the summary.ini file for the Custom Summary Page
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Settings" NumFields "3"
-
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 1" Type   "label"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 1" Text   "$(SUMMARY_INSTALLED_TO)"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 1" Left   "0"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 1" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 1" Top    "5"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 1" Bottom "15"
-
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 2" Type   "text"
-  ; The contents of this control must be set as follows in the pre function
-  ; ${MUI_INSTALLOPTIONS_READ} $1 "summary.ini" "Field 2" "HWND"
-  ; SendMessage $1 ${WM_SETTEXT} 0 "STR:$INSTDIR"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 2" state  ""
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 2" Left   "0"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 2" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 2" Top    "17"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 2" Bottom "30"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 2" flags  "READONLY"
-
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 3" Type   "label"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 3" Left   "0"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 3" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 3" Top    "130"
-  WriteINIStr "$PLUGINSDIR\summary.ini" "Field 3" Bottom "150"
-
-  ${If} ${FileExists} "$INSTDIR\${FileMainEXE}"
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Field 3" Text "$(SUMMARY_UPGRADE_CLICK)"
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Settings" NextButtonText "$(UPGRADE_BUTTON)"
-  ${Else}
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Field 3" Text "$(SUMMARY_INSTALL_CLICK)"
-    DeleteINIStr "$PLUGINSDIR\summary.ini" "Settings" NextButtonText
-  ${EndIf}
-
-
-  ; Remove the "Field 4" ini section in case the user hits back and changes the
-  ; installation directory which could change whether the make default checkbox
-  ; should be displayed.
-  DeleteINISec "$PLUGINSDIR\summary.ini" "Field 4"
-
-  ; Check if it is possible to write to HKLM
-  ClearErrors
-  WriteRegStr HKLM "Software\Mozilla" "${BrandShortName}InstallerTest" "Write Test"
-  ${Unless} ${Errors}
-    DeleteRegValue HKLM "Software\Mozilla" "${BrandShortName}InstallerTest"
-    ; Check if Pale Moon is the http handler for this user.
-    SetShellVarContext current ; Set SHCTX to the current user
-    ${IsHandlerForInstallDir} "http" $R9
-    ${If} $TmpVal == "HKLM"
-      SetShellVarContext all ; Set SHCTX to all users
-    ${EndIf}
-    ; If Pale Moon isn't the http handler for this user show the option to set
-    ; Pale Moon as the default browser.
-    ${If} "$R9" != "true"
-    ${AndIf} ${AtMostWin2008R2}
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Settings" NumFields "4"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field 4" Type   "checkbox"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field 4" Text   "$(SUMMARY_TAKE_DEFAULTS)"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field 4" Left   "0"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field 4" Right  "-1"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field 4" State  "1"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field 4" Top    "32"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field 4" Bottom "53"
-    ${EndIf}
-  ${EndUnless}
-
-  ${If} "$TmpVal" == "true"
-    ; If there is already a Type entry in the "Field 4" section with a value of
-    ; checkbox then the set as the default browser checkbox is displayed and
-    ; this text must be moved below it.
-    ReadINIStr $0 "$PLUGINSDIR\summary.ini" "Field 4" "Type"
-    ${If} "$0" == "checkbox"
-      StrCpy $0 "5"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Top    "53"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Bottom "68"
-    ${Else}
-      StrCpy $0 "4"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Top    "35"
-      WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Bottom "50"
-    ${EndIf}
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Settings" NumFields "$0"
-
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Type   "label"
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Text   "$(SUMMARY_REBOOT_REQUIRED_INSTALL)"
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Left   "0"
-    WriteINIStr "$PLUGINSDIR\summary.ini" "Field $0" Right  "-1"
-  ${EndIf}
-
-  !insertmacro MUI_HEADER_TEXT "$(SUMMARY_PAGE_TITLE)" "$(SUMMARY_PAGE_SUBTITLE)"
-
-  ; The Summary custom page has a textbox that will automatically receive
-  ; focus. This sets the focus to the Install button instead.
-  !insertmacro MUI_INSTALLOPTIONS_INITDIALOG "summary.ini"
-  GetDlgItem $0 $HWNDPARENT 1
-  System::Call "user32::SetFocus(i r0, i 0x0007, i,i)i"
-  ${MUI_INSTALLOPTIONS_READ} $1 "summary.ini" "Field 2" "HWND"
-  SendMessage $1 ${WM_SETTEXT} 0 "STR:$INSTDIR"
-  !insertmacro MUI_INSTALLOPTIONS_SHOW
-FunctionEnd
-
-Function leaveSummary
-  ; Try to delete the app executable and if we can't delete it try to find the
-  ; app's message window and prompt the user to close the app. This allows
-  ; running an instance that is located in another directory. If for whatever
-  ; reason there is no message window we will just rename the app's files and
-  ; then remove them on restart.
-  ClearErrors
-  ${DeleteFile} "$INSTDIR\${FileMainEXE}"
-  ${If} ${Errors}
-    ${ManualCloseAppPrompt} "${WindowClass}" "$(WARN_MANUALLY_CLOSE_APP_INSTALL)"
-  ${EndIf}
-FunctionEnd
-
-; When we add an optional action to the finish page the cancel button is
-; enabled. This disables it and leaves the finish button as the only choice.
-Function preFinish
-  StrCpy $PageName ""
-  ${EndInstallLog} "${BrandFullName}"
-  !insertmacro MUI_INSTALLOPTIONS_WRITE "ioSpecial.ini" "settings" "cancelenabled" "0"
-FunctionEnd
-
-################################################################################
-# Initialization Functions
-
-Function .onInit
-  ; Remove the current exe directory from the search order.
-  ; This only effects LoadLibrary calls and not implicitly loaded DLLs.
-  System::Call 'kernel32::SetDllDirectoryW(w "")'
-
-  StrCpy $PageName ""
-  StrCpy $LANGUAGE 0
-  ${SetBrandNameVars} "$EXEDIR\core\distribution\setup.ini"
-
-  ; Don't install on systems that don't support SSE2. The parameter value of
-  ; 10 is for PF_XMMI64_INSTRUCTIONS_AVAILABLE which will check whether the
-  ; SSE2 instruction set is available. Result returned in $R7.
-  System::Call "kernel32::IsProcessorFeaturePresent(i 10)i .R7"
-
-  ; Windows NT 6.0 and lower are not supported on any architecture.
-  ${Unless} ${AtLeastWin7}
-    ${If} "$R7" == "0"
-      strCpy $R7 "$(WARN_MIN_SUPPORTED_OSVER_CPU_MSG)"
-    ${Else}
-      strCpy $R7 "$(WARN_MIN_SUPPORTED_OSVER_MSG)"
-    ${EndIf}
-    MessageBox MB_OKCANCEL|MB_ICONSTOP "$R7" IDCANCEL +2
-    ExecShell "open" "${URLSystemRequirements}"
-    Quit
-  ${EndUnless}
-
-  ; SSE2 support
-  ${If} "$R7" == "0"
-    MessageBox MB_OKCANCEL|MB_ICONSTOP "$(WARN_MIN_SUPPORTED_CPU_MSG)" IDCANCEL +2
-    ExecShell "open" "${URLSystemRequirements}"
-    Quit
-  ${EndIf}
-
-!ifdef HAVE_64BIT_BUILD
-  ${Unless} ${RunningX64}
-    MessageBox MB_OKCANCEL|MB_ICONSTOP "$(WARN_MIN_SUPPORTED_OSVER_MSG)" IDCANCEL +2
-    ExecShell "open" "${URLSystemRequirements}"
-    Quit
-  ${EndUnless}
-  SetRegView 64
-!endif
-
-  ${InstallOnInitCommon} "$(WARN_MIN_SUPPORTED_OSVER_CPU_MSG)"
-
-; The commands inside this ifndef are needed prior to NSIS 3.0a2 and can be
-; removed after we require NSIS 3.0a2 or greater.
-!ifndef NSIS_PACKEDVERSION
-  System::Call 'user32::SetProcessDPIAware()'
-!endif
-
-  !insertmacro InitInstallOptionsFile "options.ini"
-  !insertmacro InitInstallOptionsFile "shortcuts.ini"
-  !insertmacro InitInstallOptionsFile "summary.ini"
-
-  WriteINIStr "$PLUGINSDIR\options.ini" "Settings" NumFields "5"
-
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 1" Type   "label"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 1" Text   "$(OPTIONS_SUMMARY)"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 1" Left   "0"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 1" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 1" Top    "0"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 1" Bottom "10"
-
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" Type   "RadioButton"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" Text   "$(OPTION_STANDARD_RADIO)"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" Left   "0"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" Top    "25"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" Bottom "35"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" State  "1"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 2" Flags  "GROUP"
-
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 3" Type   "RadioButton"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 3" Text   "$(OPTION_CUSTOM_RADIO)"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 3" Left   "0"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 3" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 3" Top    "55"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 3" Bottom "65"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 3" State  "0"
-
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 4" Type   "label"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 4" Text   "$(OPTION_STANDARD_DESC)"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 4" Left   "15"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 4" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 4" Top    "37"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 4" Bottom "57"
-
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 5" Type   "label"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 5" Text   "$(OPTION_CUSTOM_DESC)"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 5" Left   "15"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 5" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 5" Top    "67"
-  WriteINIStr "$PLUGINSDIR\options.ini" "Field 5" Bottom "87"
-
-  ; Setup the shortcuts.ini file for the Custom Shortcuts Page
-  ; Don't offer to install the quick launch shortcut on Windows 7
-  ${If} ${AtLeastWin7}
-    WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Settings" NumFields "3"
-  ${Else}
-    WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Settings" NumFields "4"
-  ${EndIf}
-
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 1" Type   "label"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 1" Text   "$(CREATE_ICONS_DESC)"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 1" Left   "0"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 1" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 1" Top    "5"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 1" Bottom "15"
-
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" Type   "checkbox"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" Text   "$(ICONS_DESKTOP)"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" Left   "0"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" Top    "20"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" Bottom "30"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" State  "1"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 2" Flags  "GROUP"
-
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 3" Type   "checkbox"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 3" Text   "$(ICONS_STARTMENU)"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 3" Left   "0"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 3" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 3" Top    "40"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 3" Bottom "50"
-  WriteINIStr "$PLUGINSDIR\shortcuts.ini" "Field 3" State  "1"
-
-  ; There must always be a core directory.
-  ${GetSize} "$EXEDIR\core\" "/S=0K" $R5 $R7 $R8
-  SectionSetSize ${APP_IDX} $R5
-
-  ; Initialize $hHeaderBitmap to prevent redundant changing of the bitmap if
-  ; the user clicks the back button
-  StrCpy $hHeaderBitmap ""
-FunctionEnd
-
-Function .onGUIEnd
-  ${OnEndCommon}
-FunctionEnd
diff --git a/application/palemoon/installer/windows/nsis/shared.nsh b/application/palemoon/installer/windows/nsis/shared.nsh
deleted file mode 100644
index 385a411a3..000000000
--- a/application/palemoon/installer/windows/nsis/shared.nsh
+++ /dev/null
@@ -1,1306 +0,0 @@
-# This Source Code Form is subject to the terms of the Mozilla Public
-# License, v. 2.0. If a copy of the MPL was not distributed with this
-# file, You can obtain one at http://mozilla.org/MPL/2.0/.
-
-!macro PostUpdate
-  ; PostUpdate is called from both session 0 and from the user session
-  ; for service updates, make sure that we only register with the user session
-  ; Otherwise ApplicationID::Set can fail intermittently with a file in use error.
-  System::Call "kernel32::GetCurrentProcessId() i.r0"
-  System::Call "kernel32::ProcessIdToSessionId(i $0, *i ${NSIS_MAX_STRLEN} r9)"
-
-  ; Determine if we're the protected UserChoice default or not. If so fix the
-  ; start menu tile.  In case there are 2 PaleMoon installations, we only do
-  ; this if the application being updated is the default.
-  ReadRegStr $0 HKCU "Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" "ProgId"
-  ${If} $0 == "PaleMoonURL"
-  ${AndIf} $9 != 0 ; We're not running in session 0
-    ReadRegStr $0 HKCU "Software\Classes\PaleMoonURL\shell\open\command" ""
-    ${GetPathFromString} "$0" $0
-    ${GetParent} "$0" $0
-    ${If} ${FileExists} "$0"
-      ${GetLongPath} "$0" $0
-    ${EndIf}
-  ${EndIf}
-
-  ${CreateShortcutsLog}
-
-  ; Remove registry entries for non-existent apps and for apps that point to our
-  ; install location in the Software\Mozilla key and uninstall registry entries
-  ; that point to our install location for both HKCU and HKLM.
-  SetShellVarContext current  ; Set SHCTX to the current user (e.g. HKCU)
-  ${RegCleanMain} "Software\Mozilla"
-  ${RegCleanUninstall}
-  ${UpdateProtocolHandlers}
-
-  ; setup the application model id registration value
-  ${InitHashAppModelId} "$INSTDIR" "Software\Mozilla\${AppName}\TaskBarIDs"
-
-  ; Win7 taskbar and start menu link maintenance
-  Call FixShortcutAppModelIDs
-
-  ClearErrors
-  WriteRegStr HKLM "Software\Mozilla" "${BrandShortName}InstallerTest" "Write Test"
-  ${If} ${Errors}
-    StrCpy $TmpVal "HKCU" ; used primarily for logging
-  ${Else}
-    SetShellVarContext all    ; Set SHCTX to all users (e.g. HKLM)
-    DeleteRegValue HKLM "Software\Mozilla" "${BrandShortName}InstallerTest"
-    StrCpy $TmpVal "HKLM" ; used primarily for logging
-    ${RegCleanMain} "Software\Mozilla"
-    ${RegCleanUninstall}
-    ${UpdateProtocolHandlers}
-    ${FixShellIconHandler} "HKLM"
-    ${SetAppLSPCategories} ${LSP_CATEGORIES}
-
-    ; Win7 taskbar and start menu link maintenance
-    Call FixShortcutAppModelIDs
-
-    ; Add the Firewall entries after an update
-    Call AddFirewallEntries
-
-    ; Only update the Clients\StartMenuInternet registry key values in HKLM if
-    ; they don't exist or this installation is the same as the one set in those
-    ; keys.
-    ${StrFilter} "${FileMainEXE}" "+" "" "" $1
-    ReadRegStr $0 HKLM "Software\Clients\StartMenuInternet\$1\DefaultIcon" ""
-    ${GetPathFromString} "$0" $0
-    ${GetParent} "$0" $0
-    ${If} ${FileExists} "$0"
-      ${GetLongPath} "$0" $0
-    ${EndIf}
-    ${If} "$0" == "$INSTDIR"
-      ${SetStartMenuInternet} "HKLM"
-    ${EndIf}
-
-    ; Only update the Clients\StartMenuInternet registry key values in HKCU if
-    ; they don't exist or this installation is the same as the one set in those
-    ; keys.  This is only done in Windows 8 to avoid a UAC prompt.
-    ${If} ${AtLeastWin8}
-      ReadRegStr $0 HKCU "Software\Clients\StartMenuInternet\$1\DefaultIcon" ""
-      ${GetPathFromString} "$0" $0
-      ${GetParent} "$0" $0
-      ${If} ${FileExists} "$0"
-        ${GetLongPath} "$0" $0
-      ${EndIf}
-      ${If} "$0" == "$INSTDIR"
-        ${SetStartMenuInternet} "HKCU"
-      ${EndIf}
-    ${EndIf}
-
-    ReadRegStr $0 HKLM "Software\mozilla.org\Mozilla" "CurrentVersion"
-    ${If} "$0" != "${GREVersion}"
-      WriteRegStr HKLM "Software\mozilla.org\Mozilla" "CurrentVersion" "${GREVersion}"
-    ${EndIf}
-  ${EndIf}
-
-  ; Migrate the application's Start Menu directory to a single shortcut in the
-  ; root of the Start Menu Programs directory.
-  ${MigrateStartMenuShortcut}
-
-  ; Update lastwritetime of the Start Menu shortcut to clear the tile cache.
-  ${If} ${AtLeastWin8}
-  ${AndIf} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-    FileOpen $0 "$SMPROGRAMS\${BrandFullName}.lnk" a
-    FileClose $0
-  ${EndIf}
-
-  ; Adds a pinned Task Bar shortcut (see MigrateTaskBarShortcut for details).
-  ${MigrateTaskBarShortcut}
-
-  ${RemoveDeprecatedKeys}
-
-  ${SetAppKeys}
-  ${FixClassKeys}
-  ${SetUninstallKeys}
-
-  ; Remove files that may be left behind by the application in the
-  ; VirtualStore directory.
-  ${CleanVirtualStore}
-
-  ${RemoveDeprecatedFiles}
-
-  ; Fix the distribution.ini file if applicable
-  ${FixDistributionsINI}
-
-  RmDir /r /REBOOTOK "$INSTDIR\${TO_BE_DELETED}"
-!macroend
-!define PostUpdate "!insertmacro PostUpdate"
-
-!macro SetAsDefaultAppGlobal
-  ${RemoveDeprecatedKeys} ; Does not use SHCTX
-
-  SetShellVarContext all      ; Set SHCTX to all users (e.g. HKLM)
-  ${SetHandlers} ; Uses SHCTX
-  ${SetStartMenuInternet} "HKLM"
-  ${FixShellIconHandler} "HKLM"
-  ${ShowShortcuts}
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-  WriteRegStr HKLM "Software\Clients\StartMenuInternet" "" "$R9"
-!macroend
-!define SetAsDefaultAppGlobal "!insertmacro SetAsDefaultAppGlobal"
-
-; Removes shortcuts for this installation. This should also remove the
-; application from Open With for the file types the application handles
-; (bug 370480).
-!macro HideShortcuts
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $0
-  StrCpy $R1 "Software\Clients\StartMenuInternet\$0\InstallInfo"
-  WriteRegDWORD HKLM "$R1" "IconsVisible" 0
-  ${If} ${AtLeastWin8}
-    WriteRegDWORD HKCU "$R1" "IconsVisible" 0
-  ${EndIf}
-
-  SetShellVarContext all  ; Set $DESKTOP to All Users
-  ${Unless} ${FileExists} "$DESKTOP\${BrandFullName}.lnk"
-    SetShellVarContext current  ; Set $DESKTOP to the current user's desktop
-  ${EndUnless}
-
-  ${If} ${FileExists} "$DESKTOP\${BrandFullName}.lnk"
-    ShellLink::GetShortCutArgs "$DESKTOP\${BrandFullName}.lnk"
-    Pop $0
-    ${If} "$0" == ""
-      ShellLink::GetShortCutTarget "$DESKTOP\${BrandFullName}.lnk"
-      Pop $0
-      ${GetLongPath} "$0" $0
-      ${If} "$0" == "$INSTDIR\${FileMainEXE}"
-        Delete "$DESKTOP\${BrandFullName}.lnk"
-      ${EndIf}
-    ${EndIf}
-  ${EndIf}
-
-  SetShellVarContext all  ; Set $SMPROGRAMS to All Users
-  ${Unless} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-    SetShellVarContext current  ; Set $SMPROGRAMS to the current user's Start
-                                ; Menu Programs directory
-  ${EndUnless}
-
-  ${If} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-    ShellLink::GetShortCutArgs "$SMPROGRAMS\${BrandFullName}.lnk"
-    Pop $0
-    ${If} "$0" == ""
-      ShellLink::GetShortCutTarget "$SMPROGRAMS\${BrandFullName}.lnk"
-      Pop $0
-      ${GetLongPath} "$0" $0
-      ${If} "$0" == "$INSTDIR\${FileMainEXE}"
-        Delete "$SMPROGRAMS\${BrandFullName}.lnk"
-      ${EndIf}
-    ${EndIf}
-  ${EndIf}
-
-  ${If} ${FileExists} "$QUICKLAUNCH\${BrandFullName}.lnk"
-    ShellLink::GetShortCutArgs "$QUICKLAUNCH\${BrandFullName}.lnk"
-    Pop $0
-    ${If} "$0" == ""
-      ShellLink::GetShortCutTarget "$QUICKLAUNCH\${BrandFullName}.lnk"
-      Pop $0
-      ${GetLongPath} "$0" $0
-      ${If} "$0" == "$INSTDIR\${FileMainEXE}"
-        Delete "$QUICKLAUNCH\${BrandFullName}.lnk"
-      ${EndIf}
-    ${EndIf}
-  ${EndIf}
-!macroend
-!define HideShortcuts "!insertmacro HideShortcuts"
-
-; Adds shortcuts for this installation. This should also add the application
-; to Open With for the file types the application handles (bug 370480).
-!macro ShowShortcuts
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $0
-  StrCpy $R1 "Software\Clients\StartMenuInternet\$0\InstallInfo"
-  WriteRegDWORD HKLM "$R1" "IconsVisible" 1
-  ${If} ${AtLeastWin8}
-    WriteRegDWORD HKCU "$R1" "IconsVisible" 1
-  ${EndIf}
-
-  SetShellVarContext all  ; Set $DESKTOP to All Users
-  ${Unless} ${FileExists} "$DESKTOP\${BrandFullName}.lnk"
-    CreateShortCut "$DESKTOP\${BrandFullName}.lnk" "$INSTDIR\${FileMainEXE}"
-    ${If} ${FileExists} "$DESKTOP\${BrandFullName}.lnk"
-      ShellLink::SetShortCutWorkingDirectory "$DESKTOP\${BrandFullName}.lnk" "$INSTDIR"
-      ${If} ${AtLeastWin7}
-      ${AndIf} "$AppUserModelID" != ""
-        ApplicationID::Set "$DESKTOP\${BrandFullName}.lnk" "$AppUserModelID" "true"
-      ${EndIf}
-    ${Else}
-      SetShellVarContext current  ; Set $DESKTOP to the current user's desktop
-      ${Unless} ${FileExists} "$DESKTOP\${BrandFullName}.lnk"
-        CreateShortCut "$DESKTOP\${BrandFullName}.lnk" "$INSTDIR\${FileMainEXE}"
-        ${If} ${FileExists} "$DESKTOP\${BrandFullName}.lnk"
-          ShellLink::SetShortCutWorkingDirectory "$DESKTOP\${BrandFullName}.lnk" \
-                                                 "$INSTDIR"
-          ${If} ${AtLeastWin7}
-          ${AndIf} "$AppUserModelID" != ""
-            ApplicationID::Set "$DESKTOP\${BrandFullName}.lnk" "$AppUserModelID" "true"
-          ${EndIf}
-        ${EndIf}
-      ${EndUnless}
-    ${EndIf}
-  ${EndUnless}
-
-  SetShellVarContext all  ; Set $SMPROGRAMS to All Users
-  ${Unless} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-    CreateShortCut "$SMPROGRAMS\${BrandFullName}.lnk" "$INSTDIR\${FileMainEXE}"
-    ${If} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-      ShellLink::SetShortCutWorkingDirectory "$SMPROGRAMS\${BrandFullName}.lnk" \
-                                             "$INSTDIR"
-      ${If} ${AtLeastWin7}
-      ${AndIf} "$AppUserModelID" != ""
-        ApplicationID::Set "$SMPROGRAMS\${BrandFullName}.lnk" "$AppUserModelID" "true"
-      ${EndIf}
-    ${Else}
-      SetShellVarContext current  ; Set $SMPROGRAMS to the current user's Start
-                                  ; Menu Programs directory
-      ${Unless} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-        CreateShortCut "$SMPROGRAMS\${BrandFullName}.lnk" "$INSTDIR\${FileMainEXE}"
-        ${If} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-          ShellLink::SetShortCutWorkingDirectory "$SMPROGRAMS\${BrandFullName}.lnk" \
-                                                 "$INSTDIR"
-          ${If} ${AtLeastWin7}
-          ${AndIf} "$AppUserModelID" != ""
-            ApplicationID::Set "$SMPROGRAMS\${BrandFullName}.lnk" "$AppUserModelID" "true"
-          ${EndIf}
-        ${EndIf}
-      ${EndUnless}
-    ${EndIf}
-  ${EndUnless}
-
-  ; Windows 7 doesn't use the QuickLaunch directory
-  ${Unless} ${AtLeastWin7}
-  ${AndUnless} ${FileExists} "$QUICKLAUNCH\${BrandFullName}.lnk"
-    CreateShortCut "$QUICKLAUNCH\${BrandFullName}.lnk" \
-                   "$INSTDIR\${FileMainEXE}"
-    ${If} ${FileExists} "$QUICKLAUNCH\${BrandFullName}.lnk"
-      ShellLink::SetShortCutWorkingDirectory "$QUICKLAUNCH\${BrandFullName}.lnk" \
-                                             "$INSTDIR"
-    ${EndIf}
-  ${EndUnless}
-!macroend
-!define ShowShortcuts "!insertmacro ShowShortcuts"
-
-!macro AddAssociationIfNoneExist FILE_TYPE
-  ClearErrors
-  EnumRegKey $7 HKCR "${FILE_TYPE}" 0
-  ${If} ${Errors}
-    WriteRegStr SHCTX "SOFTWARE\Classes\${FILE_TYPE}"  "" "PaleMoonHTML"
-  ${EndIf}
-  WriteRegStr SHCTX "SOFTWARE\Classes\${FILE_TYPE}\OpenWithProgids" "PaleMoonHTML" ""
-!macroend
-!define AddAssociationIfNoneExist "!insertmacro AddAssociationIfNoneExist"
-
-; Adds the protocol and file handler registry entries for making PaleMoon the
-; default handler (uses SHCTX).
-!macro SetHandlers
-  ${GetLongPath} "$INSTDIR\${FileMainEXE}" $8
-
-  StrCpy $0 "SOFTWARE\Classes"
-  StrCpy $2 "$\"$8$\" -osint -url $\"%1$\""
-
-  ; Associate the file handlers with PaleMoonHTML
-  ReadRegStr $6 SHCTX "$0\.htm" ""
-  ${If} "$6" != "PaleMoonHTML"
-    WriteRegStr SHCTX "$0\.htm"   "" "PaleMoonHTML"
-  ${EndIf}
-
-  ReadRegStr $6 SHCTX "$0\.html" ""
-  ${If} "$6" != "PaleMoonHTML"
-    WriteRegStr SHCTX "$0\.html"  "" "PaleMoonHTML"
-  ${EndIf}
-
-  ReadRegStr $6 SHCTX "$0\.shtml" ""
-  ${If} "$6" != "PaleMoonHTML"
-    WriteRegStr SHCTX "$0\.shtml" "" "PaleMoonHTML"
-  ${EndIf}
-
-  ReadRegStr $6 SHCTX "$0\.xht" ""
-  ${If} "$6" != "PaleMoonHTML"
-    WriteRegStr SHCTX "$0\.xht"   "" "PaleMoonHTML"
-  ${EndIf}
-
-  ReadRegStr $6 SHCTX "$0\.xhtml" ""
-  ${If} "$6" != "PaleMoonHTML"
-    WriteRegStr SHCTX "$0\.xhtml" "" "PaleMoonHTML"
-  ${EndIf}
-
-  ${AddAssociationIfNoneExist} ".oga"
-  ${AddAssociationIfNoneExist} ".ogg"
-  ${AddAssociationIfNoneExist} ".ogv"
-  ${AddAssociationIfNoneExist} ".webm"
-
-  ; An empty string is used for the 5th param because PaleMoonHTML is not a
-  ; protocol handler
-  ${AddDisabledDDEHandlerValues} "PaleMoonHTML" "$2" "$8,1" \
-                                 "${AppRegName} HTML Document" ""
-
-  ${AddDisabledDDEHandlerValues} "PaleMoonURL" "$2" "$8,1" "${AppRegName} URL" \
-                                 "true"
-  ; An empty string is used for the 4th & 5th params because the following
-  ; protocol handlers already have a display name and the additional keys
-  ; required for a protocol handler.
-  ${AddDisabledDDEHandlerValues} "ftp" "$2" "$8,1" "" ""
-  ${AddDisabledDDEHandlerValues} "http" "$2" "$8,1" "" ""
-  ${AddDisabledDDEHandlerValues} "https" "$2" "$8,1" "" ""
-!macroend
-!define SetHandlers "!insertmacro SetHandlers"
-
-; Adds the HKLM\Software\Clients\StartMenuInternet\PALEMOON.EXE registry
-; entries (does not use SHCTX).
-;
-; The values for StartMenuInternet are only valid under HKLM and there can only
-; be one installation registerred under StartMenuInternet per application since
-; the key name is derived from the main application executable.
-; http://support.microsoft.com/kb/297878
-;
-; In Windows 8 this changes slightly, you can store StartMenuInternet entries in
-; HKCU.  The icon in start menu for StartMenuInternet is deprecated as of Win7,
-; but the subkeys are what's important.  Control panel default programs looks
-; for them only in HKLM pre win8.
-;
-; Note: we might be able to get away with using the full path to the
-; application executable for the key name in order to support multiple
-; installations.
-!macro SetStartMenuInternet RegKey
-  ${GetLongPath} "$INSTDIR\${FileMainEXE}" $8
-  ${GetLongPath} "$INSTDIR\uninstall\helper.exe" $7
-
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-
-  StrCpy $0 "Software\Clients\StartMenuInternet\$R9"
-
-  WriteRegStr ${RegKey} "$0" "" "${BrandFullName}"
-
-  WriteRegStr ${RegKey} "$0\DefaultIcon" "" "$8,0"
-
-  ; The Reinstall Command is defined at
-  ; http://msdn.microsoft.com/library/default.asp?url=/library/en-us/shellcc/platform/shell/programmersguide/shell_adv/registeringapps.asp
-  WriteRegStr ${RegKey} "$0\InstallInfo" "HideIconsCommand" "$\"$7$\" /HideShortcuts"
-  WriteRegStr ${RegKey} "$0\InstallInfo" "ShowIconsCommand" "$\"$7$\" /ShowShortcuts"
-  WriteRegStr ${RegKey} "$0\InstallInfo" "ReinstallCommand" "$\"$7$\" /SetAsDefaultAppGlobal"
-
-  ClearErrors
-  ReadRegDWORD $1 ${RegKey} "$0\InstallInfo" "IconsVisible"
-  ; If the IconsVisible name value pair doesn't exist add it otherwise the
-  ; application won't be displayed in Set Program Access and Defaults.
-  ${If} ${Errors}
-    ${If} ${FileExists} "$QUICKLAUNCH\${BrandFullName}.lnk"
-      WriteRegDWORD ${RegKey} "$0\InstallInfo" "IconsVisible" 1
-    ${Else}
-      WriteRegDWORD ${RegKey} "$0\InstallInfo" "IconsVisible" 0
-    ${EndIf}
-  ${EndIf}
-
-  WriteRegStr ${RegKey} "$0\shell\open\command" "" "$\"$8$\""
-
-  WriteRegStr ${RegKey} "$0\shell\properties" "" "$(CONTEXT_OPTIONS)"
-  WriteRegStr ${RegKey} "$0\shell\properties\command" "" "$\"$8$\" -preferences"
-
-  WriteRegStr ${RegKey} "$0\shell\safemode" "" "$(CONTEXT_SAFE_MODE)"
-  WriteRegStr ${RegKey} "$0\shell\safemode\command" "" "$\"$8$\" -safe-mode"
-
-  ; Vista Capabilities registry keys
-  WriteRegStr ${RegKey} "$0\Capabilities" "ApplicationDescription" "$(REG_APP_DESC)"
-  WriteRegStr ${RegKey} "$0\Capabilities" "ApplicationIcon" "$8,0"
-  WriteRegStr ${RegKey} "$0\Capabilities" "ApplicationName" "${BrandShortName}"
-
-  WriteRegStr ${RegKey} "$0\Capabilities\FileAssociations" ".htm"   "PaleMoonHTML"
-  WriteRegStr ${RegKey} "$0\Capabilities\FileAssociations" ".html"  "PaleMoonHTML"
-  WriteRegStr ${RegKey} "$0\Capabilities\FileAssociations" ".shtml" "PaleMoonHTML"
-  WriteRegStr ${RegKey} "$0\Capabilities\FileAssociations" ".xht"   "PaleMoonHTML"
-  WriteRegStr ${RegKey} "$0\Capabilities\FileAssociations" ".xhtml" "PaleMoonHTML"
-
-  WriteRegStr ${RegKey} "$0\Capabilities\StartMenu" "StartMenuInternet" "$R9"
-
-  WriteRegStr ${RegKey} "$0\Capabilities\URLAssociations" "ftp"    "PaleMoonURL"
-  WriteRegStr ${RegKey} "$0\Capabilities\URLAssociations" "http"   "PaleMoonURL"
-  WriteRegStr ${RegKey} "$0\Capabilities\URLAssociations" "https"  "PaleMoonURL"
-
-  ; Vista Registered Application
-  WriteRegStr ${RegKey} "Software\RegisteredApplications" "${AppRegName}" "$0\Capabilities"
-!macroend
-!define SetStartMenuInternet "!insertmacro SetStartMenuInternet"
-
-; The IconHandler reference for PaleMoonHTML can end up in an inconsistent state
-; due to changes not being detected by the IconHandler for side by side
-; installs (see bug 268512). The symptoms can be either an incorrect icon or no
-; icon being displayed for files associated with PaleMoon (does not use SHCTX).
-!macro FixShellIconHandler RegKey
-  ClearErrors
-  ReadRegStr $1 ${RegKey} "Software\Classes\PaleMoonHTML\ShellEx\IconHandler" ""
-  ${Unless} ${Errors}
-    ReadRegStr $1 ${RegKey} "Software\Classes\PaleMoonHTML\DefaultIcon" ""
-    ${GetLongPath} "$INSTDIR\${FileMainEXE}" $2
-    ${If} "$1" != "$2,1"
-      WriteRegStr ${RegKey} "Software\Classes\PaleMoonHTML\DefaultIcon" "" "$2,1"
-    ${EndIf}
-  ${EndUnless}
-!macroend
-!define FixShellIconHandler "!insertmacro FixShellIconHandler"
-
-; Add Software\Mozilla\ registry entries (uses SHCTX).
-!macro SetAppKeys
-  ; Check if this is an ESR release and if so add registry values so it is
-  ; possible to determine that this is an ESR install (bug 726781).
-  ClearErrors
-  ${WordFind} "${UpdateChannel}" "esr" "E#" $3
-  ${If} ${Errors}
-    StrCpy $3 ""
-  ${Else}
-    StrCpy $3 " ESR"
-  ${EndIf}
-
-  ${GetLongPath} "$INSTDIR" $8
-  StrCpy $0 "Software\Mozilla\${BrandFullNameInternal}\${AppVersion}$3 (${ARCH} ${AB_CD})\Main"
-  ${WriteRegStr2} $TmpVal "$0" "Install Directory" "$8" 0
-  ${WriteRegStr2} $TmpVal "$0" "PathToExe" "$8\${FileMainEXE}" 0
-
-  StrCpy $0 "Software\Mozilla\${BrandFullNameInternal}\${AppVersion}$3 (${ARCH} ${AB_CD})\Uninstall"
-  ${WriteRegStr2} $TmpVal "$0" "Description" "${BrandFullNameInternal} ${AppVersion}$3 (${ARCH} ${AB_CD})" 0
-
-  StrCpy $0 "Software\Mozilla\${BrandFullNameInternal}\${AppVersion}$3 (${ARCH} ${AB_CD})"
-  ${WriteRegStr2} $TmpVal  "$0" "" "${AppVersion}$3 (${ARCH} ${AB_CD})" 0
-  ${If} "$3" == ""
-    DeleteRegValue SHCTX "$0" "ESR"
-  ${Else}
-    ${WriteRegDWORD2} $TmpVal "$0" "ESR" 1 0
-  ${EndIf}
-
-  StrCpy $0 "Software\Mozilla\${BrandFullNameInternal} ${AppVersion}$3\bin"
-  ${WriteRegStr2} $TmpVal "$0" "PathToExe" "$8\${FileMainEXE}" 0
-
-  StrCpy $0 "Software\Mozilla\${BrandFullNameInternal} ${AppVersion}$3\extensions"
-  ${WriteRegStr2} $TmpVal "$0" "Components" "$8\components" 0
-  ${WriteRegStr2} $TmpVal "$0" "Plugins" "$8\plugins" 0
-
-  StrCpy $0 "Software\Mozilla\${BrandFullNameInternal} ${AppVersion}$3"
-  ${WriteRegStr2} $TmpVal "$0" "GeckoVer" "${GREVersion}" 0
-  ${If} "$3" == ""
-    DeleteRegValue SHCTX "$0" "ESR"
-  ${Else}
-    ${WriteRegDWORD2} $TmpVal "$0" "ESR" 1 0
-  ${EndIf}
-
-  StrCpy $0 "Software\Mozilla\${BrandFullNameInternal}$3"
-  ${WriteRegStr2} $TmpVal "$0" "" "${GREVersion}" 0
-  ${WriteRegStr2} $TmpVal "$0" "CurrentVersion" "${AppVersion}$3 (${ARCH} ${AB_CD})" 0
-!macroend
-!define SetAppKeys "!insertmacro SetAppKeys"
-
-; Add uninstall registry entries. This macro tests for write access to determine
-; if the uninstall keys should be added to HKLM or HKCU.
-!macro SetUninstallKeys
-  ; Check if this is an ESR release and if so add registry values so it is
-  ; possible to determine that this is an ESR install (bug 726781).
-  ClearErrors
-  ${WordFind} "${UpdateChannel}" "esr" "E#" $3
-  ${If} ${Errors}
-    StrCpy $3 ""
-  ${Else}
-    StrCpy $3 " ESR"
-  ${EndIf}
-
-  StrCpy $0 "Software\Microsoft\Windows\CurrentVersion\Uninstall\${BrandFullNameInternal} ${AppVersion}$3 (${ARCH} ${AB_CD})"
-
-  StrCpy $2 ""
-  ClearErrors
-  WriteRegStr HKLM "$0" "${BrandShortName}InstallerTest" "Write Test"
-  ${If} ${Errors}
-    ; If the uninstall keys already exist in HKLM don't create them in HKCU
-    ClearErrors
-    ReadRegStr $2 "HKLM" $0 "DisplayName"
-    ${If} $2 == ""
-      ; Otherwise we don't have any keys for this product in HKLM so proceeed
-      ; to create them in HKCU.  Better handling for this will be done in:
-      ; Bug 711044 - Better handling for 2 uninstall icons
-      StrCpy $1 "HKCU"
-      SetShellVarContext current  ; Set SHCTX to the current user (e.g. HKCU)
-    ${EndIf}
-    ClearErrors
-  ${Else}
-    StrCpy $1 "HKLM"
-    SetShellVarContext all     ; Set SHCTX to all users (e.g. HKLM)
-    DeleteRegValue HKLM "$0" "${BrandShortName}InstallerTest"
-  ${EndIf}
-
-  ${If} $2 == ""
-    ${GetLongPath} "$INSTDIR" $8
-
-    ; Write the uninstall registry keys
-    ${WriteRegStr2} $1 "$0" "Comments" "${BrandFullNameInternal} ${AppVersion}$3 (${ARCH} ${AB_CD})" 0
-    ${WriteRegStr2} $1 "$0" "DisplayIcon" "$8\${FileMainEXE},0" 0
-    ${WriteRegStr2} $1 "$0" "DisplayName" "${BrandFullNameInternal} ${AppVersion}$3 (${ARCH} ${AB_CD})" 0
-    ${WriteRegStr2} $1 "$0" "DisplayVersion" "${AppVersion}" 0
-    ${WriteRegStr2} $1 "$0" "HelpLink" "${HelpLink}" 0
-    ${WriteRegStr2} $1 "$0" "InstallLocation" "$8" 0
-    ${WriteRegStr2} $1 "$0" "Publisher" "Moonchild Productions" 0
-    ${WriteRegStr2} $1 "$0" "UninstallString" "$\"$8\uninstall\helper.exe$\"" 0
-    DeleteRegValue SHCTX "$0" "URLInfoAbout"
-; Don't add URLUpdateInfo which is the release notes url except for the release
-; and esr channels since nightly, aurora, and beta do not have release notes.
-; Note: URLUpdateInfo is only defined in the official branding.nsi.
-!ifdef URLUpdateInfo
-!ifndef BETA_UPDATE_CHANNEL
-    ${WriteRegStr2} $1 "$0" "URLUpdateInfo" "${URLUpdateInfo}" 0
-!endif
-!endif
-    ${WriteRegStr2} $1 "$0" "URLInfoAbout" "${URLInfoAbout}" 0
-    ${WriteRegDWORD2} $1 "$0" "NoModify" 1 0
-    ${WriteRegDWORD2} $1 "$0" "NoRepair" 1 0
-
-    ${GetSize} "$8" "/S=0K" $R2 $R3 $R4
-    ${WriteRegDWORD2} $1 "$0" "EstimatedSize" $R2 0
-
-    ${If} "$TmpVal" == "HKLM"
-      SetShellVarContext all     ; Set SHCTX to all users (e.g. HKLM)
-    ${Else}
-      SetShellVarContext current  ; Set SHCTX to the current user (e.g. HKCU)
-    ${EndIf}
-  ${EndIf}
-!macroend
-!define SetUninstallKeys "!insertmacro SetUninstallKeys"
-
-; Due to a bug when associating some file handlers, only SHCTX was checked for
-; some file types such as ".pdf". SHCTX is set to HKCU or HKLM depending on
-; whether the installer has write access to HKLM. The bug would happen when
-; HCKU was checked and didn't exist since programs aren't required to set the
-; HKCU Software\Classes keys when associating handlers. The fix uses the merged
-; view in HKCR to check for existance of an existing association. This macro
-; cleans affected installations by removing the HKLM and HKCU value if it is set
-; to PaleMoonHTML when there is a value for PersistentHandler or by removing the
-; HKCU value when the HKLM value has a value other than an empty string.
-!macro FixBadFileAssociation FILE_TYPE
-  ; Only delete the default value in case the key has values for OpenWithList,
-  ; OpenWithProgids, PersistentHandler, etc.
-  ReadRegStr $0 HKCU "Software\Classes\${FILE_TYPE}" ""
-  ReadRegStr $1 HKLM "Software\Classes\${FILE_TYPE}" ""
-  ReadRegStr $2 HKCR "${FILE_TYPE}\PersistentHandler" ""
-  ${If} "$2" != ""
-    ; Since there is a persistent handler remove PaleMoonHTML as the default
-    ; value from both HKCU and HKLM if it set to PaleMoonHTML.
-    ${If} "$0" == "PaleMoonHTML"
-      DeleteRegValue HKCU "Software\Classes\${FILE_TYPE}" ""
-    ${EndIf}
-    ${If} "$1" == "PaleMoonHTML"
-      DeleteRegValue HKLM "Software\Classes\${FILE_TYPE}" ""
-    ${EndIf}
-  ${ElseIf} "$0" == "PaleMoonHTML"
-    ; Since KHCU is set to PaleMoonHTML remove PaleMoonHTML as the default value
-    ; from HKCU if HKLM is set to a value other than an empty string.
-    ${If} "$1" != ""
-      DeleteRegValue HKCU "Software\Classes\${FILE_TYPE}" ""
-    ${EndIf}
-  ${EndIf}
-!macroend
-!define FixBadFileAssociation "!insertmacro FixBadFileAssociation"
-
-; Add app specific handler registry entries under Software\Classes if they
-; don't exist (does not use SHCTX).
-!macro FixClassKeys
-  StrCpy $1 "SOFTWARE\Classes"
-
-  ; File handler keys and name value pairs that may need to be created during
-  ; install or upgrade.
-  ReadRegStr $0 HKCR ".shtml" "Content Type"
-  ${If} "$0" == ""
-    StrCpy $0 "$1\.shtml"
-    ${WriteRegStr2} $TmpVal "$1\.shtml" "" "shtmlfile" 0
-    ${WriteRegStr2} $TmpVal "$1\.shtml" "Content Type" "text/html" 0
-    ${WriteRegStr2} $TmpVal "$1\.shtml" "PerceivedType" "text" 0
-  ${EndIf}
-
-  ReadRegStr $0 HKCR ".xht" "Content Type"
-  ${If} "$0" == ""
-    ${WriteRegStr2} $TmpVal "$1\.xht" "" "xhtfile" 0
-    ${WriteRegStr2} $TmpVal "$1\.xht" "Content Type" "application/xhtml+xml" 0
-  ${EndIf}
-
-  ReadRegStr $0 HKCR ".xhtml" "Content Type"
-  ${If} "$0" == ""
-    ${WriteRegStr2} $TmpVal "$1\.xhtml" "" "xhtmlfile" 0
-    ${WriteRegStr2} $TmpVal "$1\.xhtml" "Content Type" "application/xhtml+xml" 0
-  ${EndIf}
-
-  ; Remove possibly badly associated file types
-  ${FixBadFileAssociation} ".oga"
-  ${FixBadFileAssociation} ".ogg"
-  ${FixBadFileAssociation} ".ogv"
-  ${FixBadFileAssociation} ".webm"
-!macroend
-!define FixClassKeys "!insertmacro FixClassKeys"
-
-; Updates protocol handlers if their registry open command value is for this
-; install location (uses SHCTX).
-!macro UpdateProtocolHandlers
-  ; Store the command to open the app with an url in a register for easy access.
-  ${GetLongPath} "$INSTDIR\${FileMainEXE}" $8
-  StrCpy $2 "$\"$8$\" -osint -url $\"%1$\""
-
-  ; Only set the file and protocol handlers if the existing one under HKCR is
-  ; for this install location.
-
-  ${IsHandlerForInstallDir} "PaleMoonHTML" $R9
-  ${If} "$R9" == "true"
-    ; An empty string is used for the 5th param because PaleMoonHTML is not a
-    ; protocol handler.
-    ${AddDisabledDDEHandlerValues} "PaleMoonHTML" "$2" "$8,1" \
-                                   "${AppRegName} HTML Document" ""
-  ${EndIf}
-
-  ${IsHandlerForInstallDir} "PaleMoonURL" $R9
-  ${If} "$R9" == "true"
-    ${AddDisabledDDEHandlerValues} "PaleMoonURL" "$2" "$8,1" \
-                                   "${AppRegName} URL" "true"
-  ${EndIf}
-
-  ; An empty string is used for the 4th & 5th params because the following
-  ; protocol handlers already have a display name and the additional keys
-  ; required for a protocol handler.
-  ${IsHandlerForInstallDir} "ftp" $R9
-  ${If} "$R9" == "true"
-    ${AddDisabledDDEHandlerValues} "ftp" "$2" "$8,1" "" ""
-  ${EndIf}
-
-  ${IsHandlerForInstallDir} "http" $R9
-  ${If} "$R9" == "true"
-    ${AddDisabledDDEHandlerValues} "http" "$2" "$8,1" "" ""
-  ${EndIf}
-
-  ${IsHandlerForInstallDir} "https" $R9
-  ${If} "$R9" == "true"
-    ${AddDisabledDDEHandlerValues} "https" "$2" "$8,1" "" ""
-  ${EndIf}
-!macroend
-!define UpdateProtocolHandlers "!insertmacro UpdateProtocolHandlers"
-
-; Removes various registry entries for reasons noted below (does not use SHCTX).
-!macro RemoveDeprecatedKeys
-  StrCpy $0 "SOFTWARE\Classes"
-  ; Remove support for launching gopher urls from the shell during install or
-  ; update if the DefaultIcon is from palemoon.exe.
-  ${RegCleanAppHandler} "gopher"
-
-  ; Remove support for launching chrome urls from the shell during install or
-  ; update if the DefaultIcon is from palemoon.exe (Bug 301073).
-  ${RegCleanAppHandler} "chrome"
-
-  ; Remove protocol handler registry keys added by the MS shim
-  DeleteRegKey HKLM "Software\Classes\PaleMoon.URL"
-  DeleteRegKey HKCU "Software\Classes\PaleMoon.URL"
-
-  ; Delete gopher from Capabilities\URLAssociations if it is present.
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-  StrCpy $0 "Software\Clients\StartMenuInternet\$R9"
-  ClearErrors
-  ReadRegStr $2 HKLM "$0\Capabilities\URLAssociations" "gopher"
-  ${Unless} ${Errors}
-    DeleteRegValue HKLM "$0\Capabilities\URLAssociations" "gopher"
-  ${EndUnless}
-
-  ; Delete gopher from the user's UrlAssociations if it points to PaleMoonURL.
-  StrCpy $0 "Software\Microsoft\Windows\Shell\Associations\UrlAssociations\gopher"
-  ReadRegStr $2 HKCU "$0\UserChoice" "Progid"
-  ${If} "$2" == "PaleMoonURL"
-    DeleteRegKey HKCU "$0"
-  ${EndIf}
-!macroend
-!define RemoveDeprecatedKeys "!insertmacro RemoveDeprecatedKeys"
-
-; Removes various directories and files for reasons noted below.
-!macro RemoveDeprecatedFiles
-  ; Remove talkback if it is present (remove after bug 386760 is fixed)
-  ${If} ${FileExists} "$INSTDIR\extensions\talkback@mozilla.org"
-    RmDir /r /REBOOTOK "$INSTDIR\extensions\talkback@mozilla.org"
-  ${EndIf}
-
-  ; Remove the Java Console extension (bug 1165156)
-  ${If} ${FileExists} "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0031-ABCDEFFEDCBA}"
-    RmDir /r /REBOOTOK "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0031-ABCDEFFEDCBA}"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0034-ABCDEFFEDCBA}"
-    RmDir /r /REBOOTOK "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0034-ABCDEFFEDCBA}"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0039-ABCDEFFEDCBA}"
-    RmDir /r /REBOOTOK "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0039-ABCDEFFEDCBA}"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0045-ABCDEFFEDCBA}"
-    RmDir /r /REBOOTOK "$INSTDIR\extensions\{CAFEEFAC-0016-0000-0045-ABCDEFFEDCBA}"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\extensions\{CAFEEFAC-0017-0000-0000-ABCDEFFEDCBA}"
-    RmDir /r /REBOOTOK "$INSTDIR\extensions\{CAFEEFAC-0017-0000-0000-ABCDEFFEDCBA}"
-  ${EndIf}
-!macroend
-!define RemoveDeprecatedFiles "!insertmacro RemoveDeprecatedFiles"
-
-; Converts specific partner distribution.ini from ansi to utf-8 (bug 882989)
-!macro FixDistributionsINI
-  StrCpy $1 "$INSTDIR\distribution\distribution.ini"
-  StrCpy $2 "$INSTDIR\distribution\utf8fix"
-  StrCpy $0 "0" ; Default to not attempting to fix
-
-  ; Check if the distribution.ini settings are for a partner build that needs
-  ; to have its distribution.ini converted from ansi to utf-8.
-  ${If} ${FileExists} "$1"
-    ${Unless} ${FileExists} "$2"
-      ReadINIStr $3 "$1" "Preferences" "app.distributor"
-      ${If} "$3" == "yahoo"
-        ReadINIStr $3 "$1" "Preferences" "app.distributor.channel"
-        ${If} "$3" == "de"
-        ${OrIf} "$3" == "es"
-        ${OrIf} "$3" == "e1"
-        ${OrIf} "$3" == "mx"
-          StrCpy $0 "1"
-        ${EndIf}
-      ${EndIf}
-      ; Create the utf8fix so this only runs once
-      FileOpen $3 "$2" w
-      FileClose $3
-    ${EndUnless}
-  ${EndIf}
-
-  ${If} "$0" == "1"
-    StrCpy $0 "0"
-    ClearErrors
-    ReadINIStr $3 "$1" "Global" "version"
-    ${Unless} ${Errors}
-      StrCpy $4 "$3" 2
-      ${If} "$4" == "1."
-        StrCpy $4 "$3" "" 2 ; Everything after "1."
-        ${If} $4 < 23
-          StrCpy $0 "1"
-        ${EndIf}
-      ${EndIf}
-    ${EndUnless}
-  ${EndIf}
-
-  ${If} "$0" == "1"
-    ClearErrors
-    FileOpen $3 "$1" r
-    ${If} ${Errors}
-      FileClose $3
-    ${Else}
-      StrCpy $2 "$INSTDIR\distribution\distribution.new"
-      ClearErrors
-      FileOpen $4 "$2" w
-      ${If} ${Errors}
-        FileClose $3
-        FileClose $4
-      ${Else}
-        StrCpy $0 "0" ; Default to not replacing the original distribution.ini
-        ${Do}
-          FileReadByte $3 $5
-          ${If} $5 == ""
-            ${Break}
-          ${EndIf}
-          ${If} $5 == 233 ; ansi é
-            StrCpy $0 "1"
-            FileWriteByte $4 195
-            FileWriteByte $4 169
-          ${ElseIf} $5 == 241 ; ansi ñ
-            StrCpy $0 "1"
-            FileWriteByte $4 195
-            FileWriteByte $4 177
-          ${ElseIf} $5 == 252 ; ansi ü
-            StrCpy $0 "1"
-            FileWriteByte $4 195
-            FileWriteByte $4 188
-          ${ElseIf} $5 < 128
-            FileWriteByte $4 $5
-          ${EndIf}
-        ${Loop}
-        FileClose $3
-        FileClose $4
-        ${If} "$0" == "1"
-          ClearErrors
-          Rename "$1" "$1.bak"
-          ${Unless} ${Errors}
-            Rename "$2" "$1"
-            Delete "$1.bak"
-          ${EndUnless}
-        ${Else}
-          Delete "$2"
-        ${EndIf}
-      ${EndIf}
-    ${EndIf}
-  ${EndIf}
-!macroend
-!define FixDistributionsINI "!insertmacro FixDistributionsINI"
-
-; Adds a pinned shortcut to Task Bar on update for Windows 7 and above if this
-; macro has never been called before and the application is default (see
-; PinToTaskBar for more details).
-; Since defaults handling is handled by Windows in Win8 and later, we always
-; attempt to pin a taskbar on that OS.  If Windows sets the defaults at
-; installation time, then we don't get the opportunity to run this code at
-; that time.
-!macro MigrateTaskBarShortcut
-  ${GetShortcutsLogPath} $0
-  ${If} ${FileExists} "$0"
-    ClearErrors
-    ReadINIStr $1 "$0" "TASKBAR" "Migrated"
-    ${If} ${Errors}
-      ClearErrors
-      WriteIniStr "$0" "TASKBAR" "Migrated" "true"
-      ${If} ${AtLeastWin7}
-        ; No need to check the default on Win8 and later
-        ${If} ${AtMostWin2008R2}
-          ; Check if the Pale Moon is the http handler for this user
-          SetShellVarContext current ; Set SHCTX to the current user
-          ${IsHandlerForInstallDir} "http" $R9
-          ${If} $TmpVal == "HKLM"
-            SetShellVarContext all ; Set SHCTX to all users
-          ${EndIf}
-        ${EndIf}
-        ${If} "$R9" == "true"
-        ${OrIf} ${AtLeastWin8}
-          ${PinToTaskBar}
-        ${EndIf}
-      ${EndIf}
-    ${EndIf}
-  ${EndIf}
-!macroend
-!define MigrateTaskBarShortcut "!insertmacro MigrateTaskBarShortcut"
-
-; Adds a pinned Task Bar shortcut on Windows 7 if there isn't one for the main
-; application executable already. Existing pinned shortcuts for the same
-; application model ID must be removed first to prevent breaking the pinned
-; item's lists but multiple installations with the same application model ID is
-; an edgecase. If removing existing pinned shortcuts with the same application
-; model ID removes a pinned pinned Start Menu shortcut this will also add a
-; pinned Start Menu shortcut.
-!macro PinToTaskBar
-  ${If} ${AtLeastWin7}
-    StrCpy $8 "false" ; Whether a shortcut had to be created
-    ${IsPinnedToTaskBar} "$INSTDIR\${FileMainEXE}" $R9
-    ${If} "$R9" == "false"
-      ; Find an existing Start Menu shortcut or create one to use for pinning
-      ${GetShortcutsLogPath} $0
-      ${If} ${FileExists} "$0"
-        ClearErrors
-        ReadINIStr $1 "$0" "STARTMENU" "Shortcut0"
-        ${Unless} ${Errors}
-          SetShellVarContext all ; Set SHCTX to all users
-          ${Unless} ${FileExists} "$SMPROGRAMS\$1"
-            SetShellVarContext current ; Set SHCTX to the current user
-            ${Unless} ${FileExists} "$SMPROGRAMS\$1"
-              StrCpy $8 "true"
-              CreateShortCut "$SMPROGRAMS\$1" "$INSTDIR\${FileMainEXE}"
-              ${If} ${FileExists} "$SMPROGRAMS\$1"
-                ShellLink::SetShortCutWorkingDirectory "$SMPROGRAMS\$1" \
-                                                       "$INSTDIR"
-                ${If} "$AppUserModelID" != ""
-                  ApplicationID::Set "$SMPROGRAMS\$1" "$AppUserModelID" "true"
-                ${EndIf}
-              ${EndIf}
-            ${EndUnless}
-          ${EndUnless}
-
-          ${If} ${FileExists} "$SMPROGRAMS\$1"
-            ; Count of Start Menu pinned shortcuts before unpinning.
-            ${PinnedToStartMenuLnkCount} $R9
-
-            ; Having multiple shortcuts pointing to different installations with
-            ; the same AppUserModelID (e.g. side by side installations of the
-            ; same version) will make the TaskBar shortcut's lists into an bad
-            ; state where the lists are not shown. To prevent this first
-            ; uninstall the pinned item.
-            ApplicationID::UninstallPinnedItem "$SMPROGRAMS\$1"
-
-            ; Count of Start Menu pinned shortcuts after unpinning.
-            ${PinnedToStartMenuLnkCount} $R8
-
-            ; If there is a change in the number of Start Menu pinned shortcuts
-            ; assume that unpinning unpinned a side by side installation from
-            ; the Start Menu and pin this installation to the Start Menu.
-            ${Unless} $R8 == $R9
-              ; Pin the shortcut to the Start Menu. 5381 is the shell32.dll
-              ; resource id for the "Pin to Start Menu" string.
-              InvokeShellVerb::DoIt "$SMPROGRAMS" "$1" "5381"
-            ${EndUnless}
-
-            ; Pin the shortcut to the TaskBar. 5386 is the shell32.dll resource
-            ; id for the "Pin to Taskbar" string.
-            InvokeShellVerb::DoIt "$SMPROGRAMS" "$1" "5386"
-
-            ; Delete the shortcut if it was created
-            ${If} "$8" == "true"
-              Delete "$SMPROGRAMS\$1"
-            ${EndIf}
-          ${EndIf}
-
-          ${If} $TmpVal == "HKCU"
-            SetShellVarContext current ; Set SHCTX to the current user
-          ${Else}
-            SetShellVarContext all ; Set SHCTX to all users
-          ${EndIf}
-        ${EndUnless}
-      ${EndIf}
-    ${EndIf}
-  ${EndIf}
-!macroend
-!define PinToTaskBar "!insertmacro PinToTaskBar"
-
-; Adds a shortcut to the root of the Start Menu Programs directory if the
-; application's Start Menu Programs directory exists with a shortcut pointing to
-; this installation directory. This will also remove the old shortcuts and the
-; application's Start Menu Programs directory by calling the RemoveStartMenuDir
-; macro.
-!macro MigrateStartMenuShortcut
-  ${GetShortcutsLogPath} $0
-  ${If} ${FileExists} "$0"
-    ClearErrors
-    ReadINIStr $5 "$0" "SMPROGRAMS" "RelativePathToDir"
-    ${Unless} ${Errors}
-      ClearErrors
-      ReadINIStr $1 "$0" "STARTMENU" "Shortcut0"
-      ${If} ${Errors}
-        ; The STARTMENU ini section doesn't exist.
-        ${LogStartMenuShortcut} "${BrandFullName}.lnk"
-        ${GetLongPath} "$SMPROGRAMS" $2
-        ${GetLongPath} "$2\$5" $1
-        ${If} "$1" != ""
-          ClearErrors
-          ReadINIStr $3 "$0" "SMPROGRAMS" "Shortcut0"
-          ${Unless} ${Errors}
-            ${If} ${FileExists} "$1\$3"
-              ShellLink::GetShortCutTarget "$1\$3"
-              Pop $4
-              ${If} "$INSTDIR\${FileMainEXE}" == "$4"
-                CreateShortCut "$SMPROGRAMS\${BrandFullName}.lnk" \
-                               "$INSTDIR\${FileMainEXE}"
-                ${If} ${FileExists} "$SMPROGRAMS\${BrandFullName}.lnk"
-                  ShellLink::SetShortCutWorkingDirectory "$SMPROGRAMS\${BrandFullName}.lnk" \
-                                                         "$INSTDIR"
-                  ${If} ${AtLeastWin7}
-                  ${AndIf} "$AppUserModelID" != ""
-                    ApplicationID::Set "$SMPROGRAMS\${BrandFullName}.lnk" \
-                                       "$AppUserModelID" "true"
-                  ${EndIf}
-                ${EndIf}
-              ${EndIf}
-            ${EndIf}
-          ${EndUnless}
-        ${EndIf}
-      ${EndIf}
-      ; Remove the application's Start Menu Programs directory, shortcuts, and
-      ; ini section.
-      ${RemoveStartMenuDir}
-    ${EndUnless}
-  ${EndIf}
-!macroend
-!define MigrateStartMenuShortcut "!insertmacro MigrateStartMenuShortcut"
-
-; Removes the application's start menu directory along with its shortcuts if
-; they exist and if they exist creates a start menu shortcut in the root of the
-; start menu directory (bug 598779). If the application's start menu directory
-; is not empty after removing the shortucts the directory will not be removed
-; since these additional items were not created by the installer (uses SHCTX).
-!macro RemoveStartMenuDir
-  ${GetShortcutsLogPath} $0
-  ${If} ${FileExists} "$0"
-    ; Delete Start Menu Programs shortcuts, directory if it is empty, and
-    ; parent directories if they are empty up to but not including the start
-    ; menu directory.
-    ${GetLongPath} "$SMPROGRAMS" $1
-    ClearErrors
-    ReadINIStr $2 "$0" "SMPROGRAMS" "RelativePathToDir"
-    ${Unless} ${Errors}
-      ${GetLongPath} "$1\$2" $2
-      ${If} "$2" != ""
-        ; Delete shortucts in the Start Menu Programs directory.
-        StrCpy $3 0
-        ${Do}
-          ClearErrors
-          ReadINIStr $4 "$0" "SMPROGRAMS" "Shortcut$3"
-          ; Stop if there are no more entries
-          ${If} ${Errors}
-            ${ExitDo}
-          ${EndIf}
-          ${If} ${FileExists} "$2\$4"
-            ShellLink::GetShortCutTarget "$2\$4"
-            Pop $5
-            ${If} "$INSTDIR\${FileMainEXE}" == "$5"
-              Delete "$2\$4"
-            ${EndIf}
-          ${EndIf}
-          IntOp $3 $3 + 1 ; Increment the counter
-        ${Loop}
-        ; Delete Start Menu Programs directory and parent directories
-        ${Do}
-          ; Stop if the current directory is the start menu directory
-          ${If} "$1" == "$2"
-            ${ExitDo}
-          ${EndIf}
-          ClearErrors
-          RmDir "$2"
-          ; Stop if removing the directory failed
-          ${If} ${Errors}
-            ${ExitDo}
-          ${EndIf}
-          ${GetParent} "$2" $2
-        ${Loop}
-      ${EndIf}
-      DeleteINISec "$0" "SMPROGRAMS"
-    ${EndUnless}
-  ${EndIf}
-!macroend
-!define RemoveStartMenuDir "!insertmacro RemoveStartMenuDir"
-
-; Creates the shortcuts log ini file with the appropriate entries if it doesn't
-; already exist.
-!macro CreateShortcutsLog
-  ${GetShortcutsLogPath} $0
-  ${Unless} ${FileExists} "$0"
-    ${LogStartMenuShortcut} "${BrandFullName}.lnk"
-    ${LogQuickLaunchShortcut} "${BrandFullName}.lnk"
-    ${LogDesktopShortcut} "${BrandFullName}.lnk"
-  ${EndUnless}
-!macroend
-!define CreateShortcutsLog "!insertmacro CreateShortcutsLog"
-
-; The files to check if they are in use during (un)install so the restart is
-; required message is displayed. All files must be located in the $INSTDIR
-; directory.
-!macro PushFilesToCheck
-  ; The first string to be pushed onto the stack MUST be "end" to indicate
-  ; that there are no more files to check in $INSTDIR and the last string
-  ; should be ${FileMainEXE} so if it is in use the CheckForFilesInUse macro
-  ; returns after the first check.
-  Push "end"
-  Push "AccessibleMarshal.dll"
-  Push "IA2Marshal.dll"
-  Push "freebl3.dll"
-  Push "nssckbi.dll"
-  Push "nspr4.dll"
-  Push "nssdbm3.dll"
-  Push "mozsqlite3.dll"
-  Push "xpcom.dll"
-  Push "crashreporter.exe"
-  Push "minidump-analyzer.exe"
-  Push "updater.exe"
-  Push "${FileMainEXE}"
-!macroend
-!define PushFilesToCheck "!insertmacro PushFilesToCheck"
-
-
-; Pushes the string "true" to the top of the stack if the Firewall service is
-; running and pushes the string "false" to the top of the stack if it isn't.
-!define SC_MANAGER_ALL_ACCESS 0x3F
-!define SERVICE_QUERY_CONFIG 0x0001
-!define SERVICE_QUERY_STATUS 0x0004
-!define SERVICE_RUNNING 0x4
-
-!macro IsFirewallSvcRunning
-  Push $R9
-  Push $R8
-  Push $R7
-  Push $R6
-  Push "false"
-
-  System::Call 'advapi32::OpenSCManagerW(n, n, i ${SC_MANAGER_ALL_ACCESS}) i.R6'
-  ${If} $R6 != 0
-    ; MpsSvc is the Firewall service on Windows Vista and above.
-    ; When opening the service with SERVICE_QUERY_CONFIG the return value will
-    ; be 0 if the service is not installed.
-    System::Call 'advapi32::OpenServiceW(i R6, t "MpsSvc", i ${SERVICE_QUERY_CONFIG}) i.R7'
-    ${If} $R7 != 0
-      System::Call 'advapi32::CloseServiceHandle(i R7) n'
-      ; Open the service with SERVICE_QUERY_CONFIG so its status can be queried.
-      System::Call 'advapi32::OpenServiceW(i R6, t "MpsSvc", i ${SERVICE_QUERY_STATUS}) i.R7'
-    ${Else}
-      ; SharedAccess is the Firewall service on Windows XP.
-      ; When opening the service with SERVICE_QUERY_CONFIG the return value will
-      ; be 0 if the service is not installed.
-      System::Call 'advapi32::OpenServiceW(i R6, t "SharedAccess", i ${SERVICE_QUERY_CONFIG}) i.R7'
-      ${If} $R7 != 0
-        System::Call 'advapi32::CloseServiceHandle(i R7) n'
-        ; Open the service with SERVICE_QUERY_CONFIG so its status can be
-        ; queried.
-        System::Call 'advapi32::OpenServiceW(i R6, t "SharedAccess", i ${SERVICE_QUERY_STATUS}) i.R7'
-      ${EndIf}
-    ${EndIf}
-    ; Did the calls to OpenServiceW succeed?
-    ${If} $R7 != 0
-      System::Call '*(i,i,i,i,i,i,i) i.R9'
-      ; Query the current status of the service.
-      System::Call 'advapi32::QueryServiceStatus(i R7, i $R9) i'
-      System::Call '*$R9(i, i.R8)'
-      System::Free $R9
-      System::Call 'advapi32::CloseServiceHandle(i R7) n'
-      IntFmt $R8 "0x%X" $R8
-      ${If} $R8 == ${SERVICE_RUNNING}
-        Pop $R9
-        Push "true"
-      ${EndIf}
-    ${EndIf}
-    System::Call 'advapi32::CloseServiceHandle(i R6) n'
-  ${EndIf}
-
-  Exch 1
-  Pop $R6
-  Exch 1
-  Pop $R7
-  Exch 1
-  Pop $R8
-  Exch 1
-  Pop $R9
-!macroend
-!define IsFirewallSvcRunning "!insertmacro IsFirewallSvcRunning"
-!define un.IsFirewallSvcRunning "!insertmacro IsFirewallSvcRunning"
-
-; Sets this installation as the default browser by setting the registry keys
-; under HKEY_CURRENT_USER via registry calls and using the AppAssocReg NSIS
-; plugin for Vista and above. This is a function instead of a macro so it is
-; easily called from an elevated instance of the binary. Since this can be
-; called by an elevated instance logging is not performed in this function.
-Function SetAsDefaultAppUserHKCU
-  ; Only set as the user's StartMenuInternet browser if the StartMenuInternet
-  ; registry keys are for this install.
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-  ClearErrors
-  ReadRegStr $0 HKCU "Software\Clients\StartMenuInternet\$R9\DefaultIcon" ""
-  ${If} ${Errors}
-  ${OrIf} ${AtMostWin2008R2}
-    ClearErrors
-    ReadRegStr $0 HKLM "Software\Clients\StartMenuInternet\$R9\DefaultIcon" ""
-  ${EndIf}
-  ${Unless} ${Errors}
-    ${GetPathFromString} "$0" $0
-    ${GetParent} "$0" $0
-    ${If} ${FileExists} "$0"
-      ${GetLongPath} "$0" $0
-      ${If} "$0" == "$INSTDIR"
-        WriteRegStr HKCU "Software\Clients\StartMenuInternet" "" "$R9"
-      ${EndIf}
-    ${EndIf}
-  ${EndUnless}
-
-  SetShellVarContext current  ; Set SHCTX to the current user (e.g. HKCU)
-
-  ${If} ${AtLeastWin8}
-    ${SetStartMenuInternet} "HKCU"
-    ${FixShellIconHandler} "HKCU"
-    ${FixClassKeys} ; Does not use SHCTX
-  ${EndIf}
-
-  ${SetHandlers}
-
-  ${If} ${AtLeastWinVista}
-    ; Only register as the handler on Vista and above if the app registry name
-    ; exists under the RegisteredApplications registry key. The protocol and
-    ; file handlers set previously at the user level will associate this install
-    ; as the default browser.
-    ClearErrors
-    ReadRegStr $0 HKLM "Software\RegisteredApplications" "${AppRegName}"
-    ${Unless} ${Errors}
-      ; This is all protected by a user choice hash in Windows 8 so it won't
-      ; help, but it also won't hurt.
-      AppAssocReg::SetAppAsDefaultAll "${AppRegName}"
-    ${EndUnless}
-  ${EndIf}
-  ${RemoveDeprecatedKeys}
-  ${MigrateTaskBarShortcut}
-FunctionEnd
-
-; Helper for updating the shortcut application model IDs.
-Function FixShortcutAppModelIDs
-  ${If} ${AtLeastWin7}
-  ${AndIf} "$AppUserModelID" != ""
-    ${UpdateShortcutAppModelIDs} "$INSTDIR\${FileMainEXE}" "$AppUserModelID" $0
-  ${EndIf}
-FunctionEnd
-
-; Helper for adding Firewall exceptions during install and after app update.
-Function AddFirewallEntries
-  ${IsFirewallSvcRunning}
-  Pop $0
-  ${If} "$0" == "true"
-    liteFirewallW::AddRule "$INSTDIR\${FileMainEXE}" "${BrandShortName} ($INSTDIR)"
-  ${EndIf}
-FunctionEnd
-
-; The !ifdef NO_LOG prevents warnings when compiling the installer.nsi due to
-; this function only being used by the uninstaller.nsi.
-!ifdef NO_LOG
-
-Function SetAsDefaultAppUser
-  ; On Win8, we want to avoid having a UAC prompt since we'll already have
-  ; another action for control panel default browser selection popping up
-  ; to the user.  Win8 is the first OS where the start menu keys can be
-  ; added into HKCU.  The call to SetAsDefaultAppUserHKCU will have already
-  ; set the HKCU keys for SetStartMenuInternet.
-  ${If} ${AtLeastWin8}
-    ; Check if this is running in an elevated process
-    ClearErrors
-    ${GetParameters} $0
-    ${GetOptions} "$0" "/UAC:" $0
-    ${If} ${Errors} ; Not elevated
-      Call SetAsDefaultAppUserHKCU
-    ${Else} ; Elevated - execute the function in the unelevated process
-      GetFunctionAddress $0 SetAsDefaultAppUserHKCU
-      UAC::ExecCodeSegment $0
-    ${EndIf}
-    Return ; Nothing more needs to be done
-  ${EndIf}
-
-  ; Before Win8, it is only possible to set this installation of the application
-  ; as the StartMenuInternet handler if it was added to the HKLM
-  ; StartMenuInternet registry keys.
-  ; http://support.microsoft.com/kb/297878
-
-  ; Check if this install location registered as the StartMenuInternet client
-  ${StrFilter} "${FileMainEXE}" "+" "" "" $R9
-  ClearErrors
-  ReadRegStr $0 HKCU "Software\Clients\StartMenuInternet\$R9\DefaultIcon" ""
-  ${If} ${Errors}
-  ${OrIf} ${AtMostWin2008R2}
-    ClearErrors
-    ReadRegStr $0 HKLM "Software\Clients\StartMenuInternet\$R9\DefaultIcon" ""
-  ${EndIf}
-
-  ${Unless} ${Errors}
-    ${GetPathFromString} "$0" $0
-    ${GetParent} "$0" $0
-    ${If} ${FileExists} "$0"
-      ${GetLongPath} "$0" $0
-      ${If} "$0" == "$INSTDIR"
-        ; Check if this is running in an elevated process
-        ClearErrors
-        ${GetParameters} $0
-        ${GetOptions} "$0" "/UAC:" $0
-        ${If} ${Errors} ; Not elevated
-          Call SetAsDefaultAppUserHKCU
-        ${Else} ; Elevated - execute the function in the unelevated process
-          GetFunctionAddress $0 SetAsDefaultAppUserHKCU
-          UAC::ExecCodeSegment $0
-        ${EndIf}
-        Return ; Nothing more needs to be done
-      ${EndIf}
-    ${EndIf}
-  ${EndUnless}
-
-  ; The code after ElevateUAC won't be executed on Vista and above when the
-  ; user:
-  ; a) is a member of the administrators group (e.g. elevation is required)
-  ; b) is not a member of the administrators group and chooses to elevate
-  ${ElevateUAC}
-
-  ${SetStartMenuInternet} "HKLM"
-
-  SetShellVarContext all  ; Set SHCTX to all users (e.g. HKLM)
-
-  ${FixClassKeys} ; Does not use SHCTX
-  ${FixShellIconHandler} "HKLM"
-  ${RemoveDeprecatedKeys} ; Does not use SHCTX
-
-  ClearErrors
-  ${GetParameters} $0
-  ${GetOptions} "$0" "/UAC:" $0
-  ${If} ${Errors}
-    Call SetAsDefaultAppUserHKCU
-  ${Else}
-    GetFunctionAddress $0 SetAsDefaultAppUserHKCU
-    UAC::ExecCodeSegment $0
-  ${EndIf}
-FunctionEnd
-!define SetAsDefaultAppUser "Call SetAsDefaultAppUser"
-
-!endif ; NO_LOG
diff --git a/application/palemoon/installer/windows/nsis/uninstaller.nsi b/application/palemoon/installer/windows/nsis/uninstaller.nsi
deleted file mode 100644
index 44b7c060b..000000000
--- a/application/palemoon/installer/windows/nsis/uninstaller.nsi
+++ /dev/null
@@ -1,557 +0,0 @@
-# This Source Code Form is subject to the terms of the Mozilla Public
-# License, v. 2.0. If a copy of the MPL was not distributed with this
-# file, You can obtain one at http://mozilla.org/MPL/2.0/.
-
-# Required Plugins:
-# AppAssocReg http://nsis.sourceforge.net/Application_Association_Registration_plug-in
-# CityHash    http://dxr.mozilla.org/mozilla-central/source/other-licenses/nsis/Contrib/CityHash
-# ShellLink   http://nsis.sourceforge.net/ShellLink_plug-in
-# UAC         http://nsis.sourceforge.net/UAC_plug-in
-
-; Set verbosity to 3 (e.g. no script) to lessen the noise in the build logs
-!verbose 3
-
-; 7-Zip provides better compression than the lzma from NSIS so we add the files
-; uncompressed and use 7-Zip to create a SFX archive of it
-SetDatablockOptimize on
-SetCompress off
-CRCCheck on
-
-RequestExecutionLevel user
-
-; The commands inside this ifdef require NSIS 3.0a2 or greater so the ifdef can
-; be removed after we require NSIS 3.0a2 or greater.
-!ifdef NSIS_PACKEDVERSION
-  Unicode true
-  ManifestSupportedOS all
-  ManifestDPIAware true
-!endif
-
-!addplugindir ./
-
-; On Vista and above attempt to elevate Standard Users in addition to users that
-; are a member of the Administrators group.
-!define NONADMIN_ELEVATE
-
-; prevents compiling of the reg write logging.
-!define NO_LOG
-
-!define MaintUninstallKey \
- "Software\Microsoft\Windows\CurrentVersion\Uninstall\MozillaMaintenanceService"
-
-Var TmpVal
-Var MaintCertKey
-
-; Other included files may depend upon these includes!
-; The following includes are provided by NSIS.
-!include FileFunc.nsh
-!include LogicLib.nsh
-!include MUI.nsh
-!include WinMessages.nsh
-!include WinVer.nsh
-!include WordFunc.nsh
-
-!insertmacro GetSize
-!insertmacro StrFilter
-!insertmacro WordReplace
-
-!insertmacro un.GetParent
-
-; The following includes are custom.
-!include branding.nsi
-!include defines.nsi
-!include common.nsh
-!include locales.nsi
-
-; This is named BrandShortName helper because we use this for software update
-; post update cleanup.
-VIAddVersionKey "FileDescription" "${BrandShortName} Helper"
-VIAddVersionKey "OriginalFilename" "helper.exe"
-
-!insertmacro AddDisabledDDEHandlerValues
-!insertmacro CleanVirtualStore
-!insertmacro ElevateUAC
-!insertmacro GetLongPath
-!insertmacro GetPathFromString
-!insertmacro InitHashAppModelId
-!insertmacro IsHandlerForInstallDir
-!insertmacro IsPinnedToTaskBar
-!insertmacro LogDesktopShortcut
-!insertmacro LogQuickLaunchShortcut
-!insertmacro LogStartMenuShortcut
-!insertmacro PinnedToStartMenuLnkCount
-!insertmacro RegCleanAppHandler
-!insertmacro RegCleanMain
-!insertmacro RegCleanUninstall
-!insertmacro SetAppLSPCategories
-!insertmacro SetBrandNameVars
-!insertmacro UpdateShortcutAppModelIDs
-!insertmacro UnloadUAC
-!insertmacro WriteRegDWORD2
-!insertmacro WriteRegStr2
-
-!insertmacro un.ChangeMUIHeaderImage
-!insertmacro un.CheckForFilesInUse
-!insertmacro un.CleanUpdateDirectories
-!insertmacro un.CleanVirtualStore
-!insertmacro un.DeleteShortcuts
-!insertmacro un.GetLongPath
-!insertmacro un.GetSecondInstallPath
-!insertmacro un.InitHashAppModelId
-!insertmacro un.ManualCloseAppPrompt
-!insertmacro un.RegCleanAppHandler
-!insertmacro un.RegCleanFileHandler
-!insertmacro un.RegCleanMain
-!insertmacro un.RegCleanUninstall
-!insertmacro un.RegCleanProtocolHandler
-!insertmacro un.RemoveQuotesFromPath
-!insertmacro un.RemovePrecompleteEntries
-!insertmacro un.SetAppLSPCategories
-!insertmacro un.SetBrandNameVars
-
-!include shared.nsh
-
-; Helper macros for ui callbacks. Insert these after shared.nsh
-!insertmacro OnEndCommon
-!insertmacro UninstallOnInitCommon
-
-!insertmacro un.OnEndCommon
-!insertmacro un.UninstallUnOnInitCommon
-
-Name "${BrandFullName}"
-OutFile "helper.exe"
-!ifdef HAVE_64BIT_BUILD
-  InstallDir "$PROGRAMFILES64\${BrandFullName}\"
-!else
-  InstallDir "$PROGRAMFILES32\${BrandFullName}\"
-!endif
-ShowUnInstDetails nevershow
-
-################################################################################
-# Modern User Interface - MUI
-
-!define MUI_ABORTWARNING
-!define MUI_ICON setup.ico
-!define MUI_UNICON setup.ico
-!define MUI_WELCOMEPAGE_TITLE_3LINES
-!define MUI_HEADERIMAGE
-!define MUI_HEADERIMAGE_RIGHT
-!define MUI_UNWELCOMEFINISHPAGE_BITMAP wizWatermark.bmp
-
-; Use a right to left header image when the language is right to left
-!ifdef ${AB_CD}_rtl
-!define MUI_HEADERIMAGE_BITMAP_RTL wizHeaderRTL.bmp
-!else
-!define MUI_HEADERIMAGE_BITMAP wizHeader.bmp
-!endif
-
-/**
- * Uninstall Pages
- */
-; Welcome Page
-!define MUI_PAGE_CUSTOMFUNCTION_PRE un.preWelcome
-!define MUI_PAGE_CUSTOMFUNCTION_LEAVE un.leaveWelcome
-!insertmacro MUI_UNPAGE_WELCOME
-
-; Custom Uninstall Confirm Page
-UninstPage custom un.preConfirm
-
-; Remove Files Page
-!insertmacro MUI_UNPAGE_INSTFILES
-
-; Finish Page
-
-!insertmacro MUI_UNPAGE_FINISH
-
-; Use the default dialog for IDD_VERIFY for a simple Banner
-ChangeUI IDD_VERIFY "${NSISDIR}\Contrib\UIs\default.exe"
-
-################################################################################
-# Install Sections
-; Empty section required for the installer to compile as an uninstaller
-Section ""
-SectionEnd
-
-################################################################################
-# Uninstall Sections
-
-Section "Uninstall"
-  SetDetailsPrint textonly
-  DetailPrint $(STATUS_UNINSTALL_MAIN)
-  SetDetailsPrint none
-
-  ; Delete the app exe to prevent launching the app while we are uninstalling.
-  ClearErrors
-  ${DeleteFile} "$INSTDIR\${FileMainEXE}"
-  ${If} ${Errors}
-    ; If the user closed the application it can take several seconds for it to
-    ; shut down completely. If the application is being used by another user we
-    ; can still delete the files when the system is restarted.
-    Sleep 5000
-    ${DeleteFile} "$INSTDIR\${FileMainEXE}"
-    ClearErrors
-  ${EndIf}
-
-  ; setup the application model id registration value
-  ${un.InitHashAppModelId} "$INSTDIR" "Software\Mozilla\${AppName}\TaskBarIDs"
-
-  SetShellVarContext current  ; Set SHCTX to HKCU
-  ${un.RegCleanMain} "Software\Mozilla"
-  ${un.RegCleanUninstall}
-  ${un.DeleteShortcuts}
-
-  ; Unregister resources associated with Win7 taskbar jump lists.
-  ${If} ${AtLeastWin7}
-  ${AndIf} "$AppUserModelID" != ""
-    ApplicationID::UninstallJumpLists "$AppUserModelID"
-  ${EndIf}
-
-  ; Remove the updates directory for Vista and above
-  ${un.CleanUpdateDirectories} "Mozilla\PaleMoon" "Mozilla\updates"
-
-  ; Remove any app model id's stored in the registry for this install path
-  DeleteRegValue HKCU "Software\Mozilla\${AppName}\TaskBarIDs" "$INSTDIR"
-  DeleteRegValue HKLM "Software\Mozilla\${AppName}\TaskBarIDs" "$INSTDIR"
-
-  ClearErrors
-  WriteRegStr HKLM "Software\Mozilla" "${BrandShortName}InstallerTest" "Write Test"
-  ${If} ${Errors}
-    StrCpy $TmpVal "HKCU" ; used primarily for logging
-  ${Else}
-    SetShellVarContext all  ; Set SHCTX to HKLM
-    DeleteRegValue HKLM "Software\Mozilla" "${BrandShortName}InstallerTest"
-    StrCpy $TmpVal "HKLM" ; used primarily for logging
-    ${un.RegCleanMain} "Software\Mozilla"
-    ${un.RegCleanUninstall}
-    ${un.DeleteShortcuts}
-    ${un.SetAppLSPCategories}
-  ${EndIf}
-
-  ${un.RegCleanAppHandler} "PaleMoonURL"
-  ${un.RegCleanAppHandler} "PaleMoonHTML"
-  ${un.RegCleanProtocolHandler} "ftp"
-  ${un.RegCleanProtocolHandler} "http"
-  ${un.RegCleanProtocolHandler} "https"
-
-  ClearErrors
-  ReadRegStr $R9 HKCR "PaleMoonHTML" ""
-  ; Don't clean up the file handlers if the PaleMoonHTML key still exists since
-  ; there should be a second installation that may be the default file handler
-  ${If} ${Errors}
-    ${un.RegCleanFileHandler}  ".htm"   "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".html"  "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".shtml" "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".xht"   "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".xhtml" "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".oga"  "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".ogg"  "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".ogv"  "PaleMoonHTML"
-    ${un.RegCleanFileHandler}  ".webm"  "PaleMoonHTML"
-  ${EndIf}
-
-  SetShellVarContext all  ; Set SHCTX to HKLM
-  ${un.GetSecondInstallPath} "Software\Mozilla" $R9
-  ${If} $R9 == "false"
-    SetShellVarContext current  ; Set SHCTX to HKCU
-    ${un.GetSecondInstallPath} "Software\Mozilla" $R9
-  ${EndIf}
-
-  StrCpy $0 "Software\Clients\StartMenuInternet\${FileMainEXE}\shell\open\command"
-  ReadRegStr $R1 HKLM "$0" ""
-  ${un.RemoveQuotesFromPath} "$R1" $R1
-  ${un.GetParent} "$R1" $R1
-
-  ; Only remove the StartMenuInternet key if it refers to this install location.
-  ; The StartMenuInternet registry key is independent of the default browser
-  ; settings. The XPInstall base un-installer always removes this key if it is
-  ; uninstalling the default browser and it will always replace the keys when
-  ; installing even if there is another install of PaleMoon that is set as the
-  ; default browser. Now the key is always updated on install but it is only
-  ; removed if it refers to this install location.
-  ${If} "$INSTDIR" == "$R1"
-    DeleteRegKey HKLM "Software\Clients\StartMenuInternet\${FileMainEXE}"
-    DeleteRegValue HKLM "Software\RegisteredApplications" "${AppRegName}"
-  ${EndIf}
-
-  ReadRegStr $R1 HKCU "$0" ""
-  ${un.RemoveQuotesFromPath} "$R1" $R1
-  ${un.GetParent} "$R1" $R1
-
-  ; Only remove the StartMenuInternet key if it refers to this install location.
-  ; The StartMenuInternet registry key is independent of the default browser
-  ; settings. The XPInstall base un-installer always removes this key if it is
-  ; uninstalling the default browser and it will always replace the keys when
-  ; installing even if there is another install of PaleMoon that is set as the
-  ; default browser. Now the key is always updated on install but it is only
-  ; removed if it refers to this install location.
-  ${If} "$INSTDIR" == "$R1"
-    DeleteRegKey HKCU "Software\Clients\StartMenuInternet\${FileMainEXE}"
-    DeleteRegValue HKCU "Software\RegisteredApplications" "${AppRegName}"
-  ${EndIf}
-
-  StrCpy $0 "Software\Microsoft\Windows\CurrentVersion\App Paths\${FileMainEXE}"
-  ${If} $R9 == "false"
-    DeleteRegKey HKLM "$0"
-    DeleteRegKey HKCU "$0"
-    StrCpy $0 "Software\Microsoft\MediaPlayer\ShimInclusionList\${FileMainEXE}"
-    DeleteRegKey HKLM "$0"
-    DeleteRegKey HKCU "$0"
-    StrCpy $0 "Software\Microsoft\MediaPlayer\ShimInclusionList\plugin-container.exe"
-    DeleteRegKey HKLM "$0"
-    DeleteRegKey HKCU "$0"
-    StrCpy $0 "Software\Classes\MIME\Database\Content Type\application/x-xpinstall;app=PaleMoon"
-    DeleteRegKey HKLM "$0"
-    DeleteRegKey HKCU "$0"
-  ${Else}
-    ReadRegStr $R1 HKLM "$0" ""
-    ${un.RemoveQuotesFromPath} "$R1" $R1
-    ${un.GetParent} "$R1" $R1
-    ${If} "$INSTDIR" == "$R1"
-      WriteRegStr HKLM "$0" "" "$R9"
-      ${un.GetParent} "$R9" $R1
-      WriteRegStr HKLM "$0" "Path" "$R1"
-    ${EndIf}
-  ${EndIf}
-
-  ; Remove directories and files we always control before parsing the uninstall
-  ; log so empty directories can be removed.
-  ${If} ${FileExists} "$INSTDIR\updates"
-    RmDir /r /REBOOTOK "$INSTDIR\updates"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\updated"
-    RmDir /r /REBOOTOK "$INSTDIR\updated"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\defaults\shortcuts"
-    RmDir /r /REBOOTOK "$INSTDIR\defaults\shortcuts"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\distribution"
-    RmDir /r /REBOOTOK "$INSTDIR\distribution"
-  ${EndIf}
-
-  ; Remove files that may be left behind by the application in the
-  ; VirtualStore directory.
-  ${un.CleanVirtualStore}
-
-  ; Only unregister the dll if the registration points to this installation
-  ReadRegStr $R1 HKCR "CLSID\{0D68D6D0-D93D-4D08-A30D-F00DD1F45B24}\InProcServer32" ""
-  ${If} "$INSTDIR\AccessibleMarshal.dll" == "$R1"
-    ${UnregisterDLL} "$INSTDIR\AccessibleMarshal.dll"
-  ${EndIf}
-
-  ${un.RemovePrecompleteEntries} "false"
-
-  ${If} ${FileExists} "$INSTDIR\defaults\pref\channel-prefs.js"
-    Delete /REBOOTOK "$INSTDIR\defaults\pref\channel-prefs.js"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\defaults\pref"
-    RmDir /REBOOTOK "$INSTDIR\defaults\pref"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\defaults"
-    RmDir /REBOOTOK "$INSTDIR\defaults"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\uninstall"
-    ; Remove the uninstall directory that we control
-    RmDir /r /REBOOTOK "$INSTDIR\uninstall"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\install.log"
-    Delete /REBOOTOK "$INSTDIR\install.log"
-  ${EndIf}
-  ${If} ${FileExists} "$INSTDIR\update-settings.ini"
-    Delete /REBOOTOK "$INSTDIR\update-settings.ini"
-  ${EndIf}
-
-  ; Explicitly remove empty webapprt dir in case it exists (bug 757978).
-  RmDir "$INSTDIR\webapprt\components"
-  RmDir "$INSTDIR\webapprt"
-
-  ; Remove the installation directory if it is empty
-  RmDir "$INSTDIR"
-
-  ; If PaleMoon.exe was successfully deleted yet we still need to restart to
-  ; remove other files create a dummy PaleMoon.exe.moz-delete to prevent the
-  ; installer from allowing an install without restart when it is required
-  ; to complete an uninstall.
-  ${If} ${RebootFlag}
-    ; Admin is required to delete files on reboot so only add the moz-delete if
-    ; the user is an admin. After calling UAC::IsAdmin $0 will equal 1 if the
-    ; user is an admin.
-    UAC::IsAdmin
-    ${If} "$0" == "1"
-      ${Unless} ${FileExists} "$INSTDIR\${FileMainEXE}.moz-delete"
-        FileOpen $0 "$INSTDIR\${FileMainEXE}.moz-delete" w
-        FileWrite $0 "Will be deleted on restart"
-        Delete /REBOOTOK "$INSTDIR\${FileMainEXE}.moz-delete"
-        FileClose $0
-      ${EndUnless}
-    ${EndIf}
-  ${EndIf}
-
-  ; Refresh desktop icons otherwise the start menu internet item won't be
-  ; removed and other ugly things will happen like recreation of the app's
-  ; clients registry key by the OS under some conditions.
-  System::Call "shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i 0, i 0, i 0)"
-
-  ; Users who uninstall then reinstall expecting PaleMoon to use a clean profile
-  ; may be surprised during first-run. This key is checked during startup of PaleMoon and
-  ; subsequently deleted after checking. If the value is found during startup
-  ; the browser will offer to Reset PaleMoon. We use the UpdateChannel to match
-  ; uninstalls of PaleMoon-release with reinstalls of PaleMoon-release, for example.
-  WriteRegStr HKCU "Software\Mozilla\PaleMoon" "Uninstalled-${UpdateChannel}" "True"
-
-  ${un.IsFirewallSvcRunning}
-  Pop $0
-  ${If} "$0" == "true"
-    liteFirewallW::RemoveRule "$INSTDIR\${FileMainEXE}" "${BrandShortName} ($INSTDIR)"
-  ${EndIf}
-SectionEnd
-
-################################################################################
-# Language
-
-!insertmacro MOZ_MUI_LANGUAGE 'baseLocale'
-!verbose push
-!verbose 3
-!include "overrideLocale.nsh"
-!include "customLocale.nsh"
-!verbose pop
-
-; Set this after the locale files to override it if it is in the locale. Using
-; " " for BrandingText will hide the "Nullsoft Install System..." branding.
-BrandingText " "
-
-################################################################################
-# Page pre, show, and leave functions
-
-Function un.preWelcome
-  ${If} ${FileExists} "$INSTDIR\distribution\modern-wizard.bmp"
-    Delete "$PLUGINSDIR\modern-wizard.bmp"
-    CopyFiles /SILENT "$INSTDIR\distribution\modern-wizard.bmp" "$PLUGINSDIR\modern-wizard.bmp"
-  ${EndIf}
-FunctionEnd
-
-Function un.leaveWelcome
-  ${If} ${FileExists} "$INSTDIR\${FileMainEXE}"
-    Banner::show /NOUNLOAD "$(BANNER_CHECK_EXISTING)"
-
-    ; If the message window has been found previously give the app an additional
-    ; five seconds to close.
-    ${If} "$TmpVal" == "FoundMessageWindow"
-      Sleep 5000
-    ${EndIf}
-
-    ${PushFilesToCheck}
-
-    ${un.CheckForFilesInUse} $TmpVal
-
-    Banner::destroy
-
-    ; If there are files in use $TmpVal will be "true"
-    ${If} "$TmpVal" == "true"
-      ; If the message window is found the call to ManualCloseAppPrompt will
-      ; abort leaving the value of $TmpVal set to "FoundMessageWindow".
-      StrCpy $TmpVal "FoundMessageWindow"
-      ${un.ManualCloseAppPrompt} "${WindowClass}" "$(WARN_MANUALLY_CLOSE_APP_UNINSTALL)"
-      ; If the message window is not found set $TmpVal to "true" so the restart
-      ; required message is displayed.
-      StrCpy $TmpVal "true"
-    ${EndIf}
-  ${EndIf}
-FunctionEnd
-
-Function un.preConfirm
-  ${If} ${FileExists} "$INSTDIR\distribution\modern-header.bmp"
-  ${AndIf} $hHeaderBitmap == ""
-    Delete "$PLUGINSDIR\modern-header.bmp"
-    CopyFiles /SILENT "$INSTDIR\distribution\modern-header.bmp" "$PLUGINSDIR\modern-header.bmp"
-    ${un.ChangeMUIHeaderImage} "$PLUGINSDIR\modern-header.bmp"
-  ${EndIf}
-
-  ; Setup the unconfirm.ini file for the Custom Uninstall Confirm Page
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Settings" NumFields "3"
-
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 1" Type   "label"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 1" Text   "$(UN_CONFIRM_UNINSTALLED_FROM)"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 1" Left   "0"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 1" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 1" Top    "5"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 1" Bottom "15"
-
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 2" Type   "text"
-  ; The contents of this control must be set as follows in the pre function
-  ; ${MUI_INSTALLOPTIONS_READ} $1 "unconfirm.ini" "Field 2" "HWND"
-  ; SendMessage $1 ${WM_SETTEXT} 0 "STR:$INSTDIR"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 2" State  ""
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 2" Left   "0"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 2" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 2" Top    "17"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 2" Bottom "30"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 2" flags  "READONLY"
-
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 3" Type   "label"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 3" Text   "$(UN_CONFIRM_CLICK)"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 3" Left   "0"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 3" Right  "-1"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 3" Top    "130"
-  WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 3" Bottom "150"
-
-  ${If} "$TmpVal" == "true"
-    WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 4" Type   "label"
-    WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 4" Text   "$(SUMMARY_REBOOT_REQUIRED_UNINSTALL)"
-    WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 4" Left   "0"
-    WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 4" Right  "-1"
-    WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 4" Top    "35"
-    WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Field 4" Bottom "45"
-
-    WriteINIStr "$PLUGINSDIR\unconfirm.ini" "Settings" NumFields "4"
-  ${EndIf}
-
-  !insertmacro MUI_HEADER_TEXT "$(UN_CONFIRM_PAGE_TITLE)" "$(UN_CONFIRM_PAGE_SUBTITLE)"
-  ; The Summary custom page has a textbox that will automatically receive
-  ; focus. This sets the focus to the Install button instead.
-  !insertmacro MUI_INSTALLOPTIONS_INITDIALOG "unconfirm.ini"
-  GetDlgItem $0 $HWNDPARENT 1
-  System::Call "user32::SetFocus(i r0, i 0x0007, i,i)i"
-  ${MUI_INSTALLOPTIONS_READ} $1 "unconfirm.ini" "Field 2" "HWND"
-  SendMessage $1 ${WM_SETTEXT} 0 "STR:$INSTDIR"
-  !insertmacro MUI_INSTALLOPTIONS_SHOW
-FunctionEnd
-
-################################################################################
-# Initialization Functions
-
-Function .onInit
-  ; Remove the current exe directory from the search order.
-  ; This only effects LoadLibrary calls and not implicitly loaded DLLs.
-  System::Call 'kernel32::SetDllDirectoryW(w "")'
-
-  ; We need this set up for most of the helper.exe operations.
-  ${UninstallOnInitCommon}
-FunctionEnd
-
-Function un.onInit
-  ; Remove the current exe directory from the search order.
-  ; This only effects LoadLibrary calls and not implicitly loaded DLLs.
-  System::Call 'kernel32::SetDllDirectoryW(w "")'
-
-  StrCpy $LANGUAGE 0
-
-  ${un.UninstallUnOnInitCommon}
-
-; The commands inside this ifndef are needed prior to NSIS 3.0a2 and can be
-; removed after we require NSIS 3.0a2 or greater.
-!ifndef NSIS_PACKEDVERSION
-  ${If} ${AtLeastWinVista}
-    System::Call 'user32::SetProcessDPIAware()'
-  ${EndIf}
-!endif
-
-  !insertmacro InitInstallOptionsFile "unconfirm.ini"
-FunctionEnd
-
-Function .onGUIEnd
-  ${OnEndCommon}
-FunctionEnd
-
-Function un.onGUIEnd
-  ${un.OnEndCommon}
-FunctionEnd
diff --git a/application/palemoon/installer/windows/nsis/updater_append.ini b/application/palemoon/installer/windows/nsis/updater_append.ini
deleted file mode 100644
index af7742c12..000000000
--- a/application/palemoon/installer/windows/nsis/updater_append.ini
+++ /dev/null
@@ -1,12 +0,0 @@
-
-; IMPORTANT: This file should always start with a newline in case a locale
-; provided updater.ini does not end with a newline.
-; Application to launch after an update has been successfully applied. This
-; must be in the same directory or a sub-directory of the directory of the
-; application executable that initiated the software update.
-[PostUpdateWin]
-; ExeRelPath is the path to the PostUpdateWin executable relative to the
-; application executable.
-ExeRelPath=uninstall\helper.exe
-; ExeArg is the argument to pass to the PostUpdateWin exe
-ExeArg=/PostUpdate