1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
|
@//
@// Copyright (c) 2013 The WebRTC project authors. All Rights Reserved.
@//
@// Use of this source code is governed by a BSD-style license
@// that can be found in the LICENSE file in the root of the source
@// tree. An additional intellectual property rights grant can be found
@// in the file PATENTS. All contributing project authors may
@// be found in the AUTHORS file in the root of the source tree.
@//
@// This file was originally licensed as follows. It has been
@// relicensed with permission from the copyright holders.
@//
@//
@// File Name: armSP_FFT_CToC_SC16_Radix4_unsafe_s.s
@// OpenMAX DL: v1.0.2
@// Last Modified Revision: 7761
@// Last Modified Date: Wed, 26 Sep 2007
@//
@// (c) Copyright 2007-2008 ARM Limited. All Rights Reserved.
@//
@//
@//
@// Description:
@// Compute a Radix 4 FFT stage for a N point complex signal
@//
@//
@// Include standard headers
#include "dl/api/armCOMM_s.h"
#include "dl/api/omxtypes_s.h"
@// Import symbols required from other files
@// (For example tables)
@// Set debugging level
@//DEBUG_ON SETL {TRUE}
@// Guarding implementation by the processor name
@// Guarding implementation by the processor name
@// Import symbols required from other files
@// (For example tables)
@//Input Registers
#define pSrc r0
#define pDst r2
#define pTwiddle r1
#define subFFTNum r6
#define subFFTSize r7
@//Output Registers
@//Local Scratch Registers
#define grpCount r3
#define pointStep r4
#define outPointStep r5
#define stepTwiddle r12
#define setCount r14
#define srcStep r8
#define setStep r9
#define dstStep r10
#define twStep r11
#define t1 r3
@// Neon Registers
#define dW1 D0.S16
#define dW2 D1.S16
#define dW3 D2.S16
#define dXr0 D4.S16
#define dXi0 D5.S16
#define dXr1 D6.S16
#define dXi1 D7.S16
#define dXr2 D8.S16
#define dXi2 D9.S16
#define dXr3 D10.S16
#define dXi3 D11.S16
#define dYr0 D12.S16
#define dYi0 D13.S16
#define dYr1 D14.S16
#define dYi1 D15.S16
#define dYr2 D16.S16
#define dYi2 D17.S16
#define dYr3 D18.S16
#define dYi3 D19.S16
#define qT0 Q8.S32
#define qT1 Q9.S32
#define qT2 Q6.S32
#define qT3 Q7.S32
#define dZr0 D20.S16
#define dZi0 D21.S16
#define dZr1 D22.S16
#define dZi1 D23.S16
#define dZr2 D24.S16
#define dZi2 D25.S16
#define dZr3 D26.S16
#define dZi3 D27.S16
#define qY0 Q6.S16
#define qY1 Q7.S16
#define qY2 Q8.S16
#define qY3 Q9.S16
#define qX0 Q2.S16
#define qZ0 Q10.S16
#define qZ1 Q11.S16
#define qZ2 Q12.S16
#define qZ3 Q13.S16
.MACRO FFTSTAGE scaled, inverse , name
@// Define stack arguments
@// Update grpCount and grpSize rightaway inorder to reuse pGrpCount and pGrpSize regs
LSL grpCount,subFFTSize,#2
LSR subFFTNum,subFFTNum,#2
MOV subFFTSize,grpCount
@// pOut0+1 increments pOut0 by 4 bytes
@// pOut0+outPointStep == increment of 4*outPointStep bytes = size bytes
MOV stepTwiddle,#0
SMULBB outPointStep,grpCount,subFFTNum
@// pT0+1 increments pT0 by 4 bytes
@// pT0+pointStep = increment of 4*pointStep bytes = grpSize bytes
LSL pointStep,subFFTNum,#2 @// 2*grpSize
VLD1 dW1,[pTwiddle, :64] @//[wi | wr]
MOV srcStep,pointStep,LSL #1 @// srcStep = 2*pointStep
VLD1 dW2,[pTwiddle, :64] @//[wi | wr]
ADD setStep,srcStep,pointStep @// setStep = 3*pointStep
SUB srcStep,srcStep,#16 @// srcStep = 2*pointStep-16
VLD1 dW3,[pTwiddle, :64]
@//RSB setStep,setStep,#16 @// setStep = - 3*pointStep+16
RSB setStep,setStep,#0 @// setStep = - 3*pointStep
MOV dstStep,outPointStep,LSL #1
ADD dstStep,dstStep,outPointStep @// dstStep = 3*outPointStep
RSB dstStep,dstStep,#16 @// dstStep = - 3*outPointStep+16
grpLoop\name:
VLD2 {dXr0,dXi0},[pSrc, :128],pointStep @// data[0]
ADD stepTwiddle,stepTwiddle,pointStep
VLD2 {dXr1,dXi1},[pSrc, :128],pointStep @// data[1]
ADD pTwiddle,pTwiddle,stepTwiddle @// set pTwiddle to the first point
VLD2 {dXr2,dXi2},[pSrc, :128],pointStep @// data[2]
MOV twStep,stepTwiddle,LSL #2
VLD2 {dXr3,dXi3},[pSrc, :128],setStep @// data[3] & reset pSrc
SUB twStep,stepTwiddle,twStep @// twStep = -3*stepTwiddle
MOV setCount,pointStep,LSR #2
ADD pSrc,pSrc,#16 @// set pSrc to data[0] of the next set
ADD pSrc,pSrc,pointStep @// increment to data[1] of the next set
@// Loop on the sets : 4 at a time
setLoop\name:
SUBS setCount,setCount,#4 @// decrement the loop counter
.ifeqs "\inverse", "TRUE"
VMULL qT0,dXr1,dW1[0]
VMLAL qT0,dXi1,dW1[1] @// real part
VMULL qT1,dXi1,dW1[0]
VMLSL qT1,dXr1,dW1[1] @// imag part
.ELSE
VMULL qT0,dXr1,dW1[0]
VMLSL qT0,dXi1,dW1[1] @// real part
VMULL qT1,dXi1,dW1[0]
VMLAL qT1,dXr1,dW1[1] @// imag part
.ENDIF
VLD2 {dXr1,dXi1},[pSrc, :128],pointStep @// data[1]
.ifeqs "\inverse", "TRUE"
VMULL qT2,dXr2,dW2[0]
VMLAL qT2,dXi2,dW2[1] @// real part
VMULL qT3,dXi2,dW2[0]
VMLSL qT3,dXr2,dW2[1] @// imag part
.ELSE
VMULL qT2,dXr2,dW2[0]
VMLSL qT2,dXi2,dW2[1] @// real part
VMULL qT3,dXi2,dW2[0]
VMLAL qT3,dXr2,dW2[1] @// imag part
.ENDIF
VRSHRN dZr1,qT0,#15
VRSHRN dZi1,qT1,#15
VLD2 {dXr2,dXi2},[pSrc, :128],pointStep @// data[2]
.ifeqs "\inverse", "TRUE"
VMULL qT0,dXr3,dW3[0]
VMLAL qT0,dXi3,dW3[1] @// real part
VMULL qT1,dXi3,dW3[0]
VMLSL qT1,dXr3,dW3[1] @// imag part
.ELSE
VMULL qT0,dXr3,dW3[0]
VMLSL qT0,dXi3,dW3[1] @// real part
VMULL qT1,dXi3,dW3[0]
VMLAL qT1,dXr3,dW3[1] @// imag part
.ENDIF
VRSHRN dZr2,qT2,#15
VRSHRN dZi2,qT3,#15
VRSHRN dZr3,qT0,#15
VRSHRN dZi3,qT1,#15
VLD2 {dXr3,dXi3},[pSrc, :128],setStep @// data[3] & update pSrc for the next set
.ifeqs "\scaled", "TRUE"
@// finish first stage of 4 point FFT
VHADD qY0,qX0,qZ2
VHSUB qY2,qX0,qZ2
VLD2 {dXr0,dXi0},[pSrc, :128]! @// data[0]
VHADD qY1,qZ1,qZ3
VHSUB qY3,qZ1,qZ3
@// finish second stage of 4 point FFT
.ifeqs "\inverse", "TRUE"
VHSUB qZ0,qY2,qY1
VHADD dZr2,dYr0,dYi3
VST2 {dZr0,dZi0},[pDst, :128],outPointStep
VHSUB dZi2,dYi0,dYr3
VHADD qZ1,qY2,qY1
VST2 {dZr2,dZi2},[pDst, :128],outPointStep
VHSUB dZr3,dYr0,dYi3
VST2 {dZr1,dZi1},[pDst, :128],outPointStep
VHADD dZi3,dYi0,dYr3
VST2 {dZr3,dZi3},[pDst, :128],dstStep
.ELSE
VHSUB qZ0,qY2,qY1
VHSUB dZr3,dYr0,dYi3
VST2 {dZr0,dZi0},[pDst, :128],outPointStep
VHADD dZi3,dYi0,dYr3
VHADD qZ1,qY2,qY1
VST2 {dZr3,dZi3},[pDst, :128],outPointStep
VHADD dZr2,dYr0,dYi3
VHSUB dZi2,dYi0,dYr3
VST2 {dZr1,dZi1},[pDst, :128],outPointStep
VST2 {dZr2,dZi2},[pDst, :128],dstStep
.ENDIF
.ELSE
@// finish first stage of 4 point FFT
VADD qY0,qX0,qZ2
VSUB qY2,qX0,qZ2
VLD2 {dXr0,dXi0},[pSrc]! @// data[0]
VADD qY1,qZ1,qZ3
VSUB qY3,qZ1,qZ3
@// finish second stage of 4 point FFT
.ifeqs "\inverse", "TRUE"
VSUB qZ0,qY2,qY1
VADD dZr2,dYr0,dYi3
VST2 {dZr0,dZi0},[pDst, :128],outPointStep
VSUB dZi2,dYi0,dYr3
VADD qZ1,qY2,qY1
VST2 {dZr2,dZi2},[pDst, :128],outPointStep
VSUB dZr3,dYr0,dYi3
VST2 {dZr1,dZi1},[pDst, :128],outPointStep
VADD dZi3,dYi0,dYr3
VST2 {dZr3,dZi3},[pDst, :128],dstStep
.ELSE
VSUB qZ0,qY2,qY1
VSUB dZr3,dYr0,dYi3
VST2 {dZr0,dZi0},[pDst, :128],outPointStep
VADD dZi3,dYi0,dYr3
VADD qZ1,qY2,qY1
VST2 {dZr3,dZi3},[pDst, :128],outPointStep
VADD dZr2,dYr0,dYi3
VSUB dZi2,dYi0,dYr3
VST2 {dZr1,dZi1},[pDst, :128],outPointStep
VST2 {dZr2,dZi2},[pDst, :128],dstStep
.ENDIF
.ENDIF
ADD pSrc,pSrc,pointStep @// increment to data[1] of the next set
BGT setLoop\name
VLD1 dW1,[pTwiddle, :64],stepTwiddle @//[wi | wr]
SUBS grpCount,grpCount,#4 @// subtract 4 since grpCount multiplied by 4
VLD1 dW2,[pTwiddle, :64],stepTwiddle @//[wi | wr]
ADD pSrc,pSrc,srcStep @// increment pSrc for the next grp
VLD1 dW3,[pTwiddle, :64],twStep @//[wi | wr]
BGT grpLoop\name
@// Reset and Swap pSrc and pDst for the next stage
MOV t1,pDst
SUB pDst,pSrc,outPointStep,LSL #2 @// pDst -= size; pSrc -= 4*size bytes
SUB pSrc,t1,outPointStep
.endm
M_START armSP_FFTFwd_CToC_SC16_Radix4_OutOfPlace_unsafe,r4
FFTSTAGE "FALSE","FALSE",FWD
M_END
M_START armSP_FFTInv_CToC_SC16_Radix4_OutOfPlace_unsafe,r4
FFTSTAGE "FALSE","TRUE",INV
M_END
M_START armSP_FFTFwd_CToC_SC16_Sfs_Radix4_OutOfPlace_unsafe,r4
FFTSTAGE "TRUE","FALSE",FWDSFS
M_END
M_START armSP_FFTInv_CToC_SC16_Sfs_Radix4_OutOfPlace_unsafe,r4
FFTSTAGE "TRUE","TRUE",INVSFS
M_END
.END
|